# $Id: PKGBUILD 48564 2011-06-02 12:21:22Z bluewind $
# Maintainer: Florian Pritz <flo@xinu.at>

_pkgbasename=glew
pkgname=lib32-$_pkgbasename
pkgver=1.6.0
pkgrel=1
pkgdesc="A cross-platform C/C++ extension loading library (32 bit)"
arch=('x86_64')
url="http://glew.sourceforge.net"
license=('BSD' 'MIT' 'GPL')
depends=('lib32-libxmu' 'lib32-libxi' 'lib32-mesa' "$_pkgbasename>=$pkgver")
makedepends=('gcc-multilib')
source=(http://downloads.sourceforge.net/${_pkgbasename}/${_pkgbasename}-${pkgver}.tgz)
md5sums=('7dfbb444b5a4e125bc5dba0aef403082')
sha1sums=('ed555d15d0f01239b262c4cf803e97d60d8a18b6')

build() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"
  sed -i 's|CC = cc|CC = gcc -m32|' config/Makefile.linux
  sed -i 's|LD = cc|LD = gcc -m32|' config/Makefile.linux
  sed -i 's|lib64|lib32|' config/Makefile.linux
  make
}

package() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"
  make GLEW_DEST="${pkgdir}/usr" install
  chmod 0755 "${pkgdir}/usr/lib32/libGLEW.so.${pkgver}"

  rm -rf "${pkgdir}"/usr/{include,bin}
  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}