# $Id: PKGBUILD 206112 2014-02-18 14:55:21Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=grilo-plugins
pkgname=grilo-plugins-nonprism
pkgver=0.2.11
pkgrel=1
pkgdesc="Plugins for Grilo, without libgdata support and gnome-online-accounts recommendation"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=(LGPL)
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=(grilo sqlite libgcrypt)
makedepends=(gupnp-av gmime libtracker-sparql libdmapsharing
             json-glib intltool avahi itstool)
optdepends=('gupnp-av: uPnP plugin'
            'gmime: Podcasts plugin'
            'libtracker-sparql: Tracker plugin'
            'libdmapsharing: DMAP sharing plugin'
            'json-glib: TMDb plugin'
            'avahi: Freebox plugin')
options=('!emptydirs')
groups=('gnome')
source=(http://ftp.gnome.org/pub/gnome/sources/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.xz)
sha256sums=('a2ac4ad28f3ead53d00d99653b2fb2d19cd5d9cfc33a16e7e82477223d089944')

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static \
    --enable-shoutcast --disable-pocket
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}