#Maintainer: TingPing tingping@tingping.se
#Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.9.4
pkgrel=2
pkgdesc='A GTK+ based IRC client without non-free browser reference'
arch=('i686' 'x86_64' 'mips64el')
url='http://www.hexchat.org/'
license=('GPL')
options=('!libtool')
replaces=('hexchat')
conflicts=('hexchat')
provides=("hexchat=$pkgver")
depends=('gtk2' 'openssl' 'dbus-glib' 'hicolor-icon-theme' 'libnotify' 'libproxy')
makedepends=('perl' 'python2' 'tcl')
optdepends=('enchant: for spell check'
            'perl: for perl plugin'
            'tcl: for tcl plugin'
            'python2: for python plugin')
install="$_pkgname.install"
source=("https://github.com/downloads/hexchat/hexchat/hexchat-$pkgver.tar.xz"
        'remove-non-free-suggestion.patch'
        'no-firefox.patch')
md5sums=('5609cac7200fc91be57196501aaf07fa'
         '978da875b73d9570134a1e87af54f94b'
         '8934416304ed77161da0883d5b06e7b8')

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  patch -p1 -i "${srcdir}/remove-non-free-suggestion.patch"
  patch -p1 -i "${srcdir}/no-firefox.patch"
  mkdir m4
  chmod +x autogen.sh
  ./autogen.sh
  ./configure --prefix=/usr \
    --enable-openssl --enable-dbus --enable-nls --enable-ipv6 --enable-shm --enable-spell=static
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -D -m644 "share/icons/hexchat.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/hexchat.svg"
}