# $Id: PKGBUILD 198149 2013-10-30 13:05:35Z allan $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@parabola.nu>

_pkgname=libdrm
pkgname=libdrm-nvfx
pkgver=2.4.33
pkgrel=4
pkgdesc="Userspace interface to kernel DRM services for Nouveau NVFX [NV30 and NV40] (GeForce FX - 7000 series card) video card family"
arch=(i686 x86_64 mips64el)
license=('custom')
depends=('glibc' 'libpciaccess')
makedepends=('valgrind' 'clang')
provides=('libdrm')
conflicts=('libdrm')
checkdepends=('cairo')
options=('!libtool')
url="http://dri.freedesktop.org/"
source=(http://dri.freedesktop.org/$_pkgname/$_pkgname-$pkgver.tar.bz2
        COPYING)
sha256sums=('2d7b9d94ada0e3a6ede6243509883df2ded01c2983e24322759a366283898fea'
            '9631d4f694952e3e6ae5a05534c2e93e994e47d3413677a3a00e45c8cef6db93')

build() {
  cd $_pkgname-$pkgver

  # pthread is useless in Linux
  sed -i "/pthread-stubs/d" configure.ac
  autoreconf --force --install
  
  # gcc 4.8 introduces graphic corruption and X crashes with nouveau cards (nv44)
  # http://gcc.gnu.org/ml/gcc-help/2013-07/msg00103.html
  # we use clang compiler meanwhile
  export CC=clang

  ./configure --prefix=/usr --enable-udev \
    --enable-nouveau-experimental-api \
    --enable-libkms --disable-intel --disable-radeon

  make
}

check() {
  cd $_pkgname-$pkgver
  make -k check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -m755 -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/"
}