# $Id: PKGBUILD 121113 2011-04-29 02:56:31Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=alpine
pkgver=2.00
pkgrel=13
_patchlevel=79
pkgdesc="The Apache-licensed PINE (a tool for reading, sending, and managing electronic messages)"
arch=('i686' 'x86_64')
url="http://www.washington.edu/alpine/"
license=('APACHE')
depends=('libldap' 'krb5' 'gettext')
optdepends=('aspell: for spell-checking support')
provides=('pine')
conflicts=('pine')
replaces=('pine')
options=('!makeflags')
source=(ftp://ftp.cac.washington.edu/${pkgname}/${pkgname}.tar.bz2 \
        http://staff.washington.edu/chappa/alpine/patches/alpine-${pkgver}/all_${_patchlevel}.patch.gz \
        2.00-lpam.patch CVE-2008-5514.patch)
md5sums=('84e44cbf71ed674800a5d57eed9c1c52'
         'd7dffd121c9a1cac4c458c0ff71df1ce'
         'cd3911c16fc6a072e853c0ccfc35857c'
         '1b52a54a656979116c09fb1d948a4325')
sha1sums=('dcbd3c5419954f484ccf706feaba31ce48cdebc4'
          'd3acbf0e46c50feb2e822ef3bdc0a0f43c007294'
          '1b39525f91ebd5a9de5a1e04f5554f6fa5f58ae3'
          'bc61d76a237ff42b00b3f60f2e6fc5c45e261dbb')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 < ../all_${_patchlevel}.patch
  patch -p1 < ../2.00-lpam.patch
  patch -p1 < ../CVE-2008-5514.patch
  ./configure --prefix=/usr --without-passfile --without-tcl \
    --disable-shared --with-system-pinerc=/etc/alpine.d/pine.conf \
    --with-system-fixed-pinerc=/etc/alpine.d/pine.conf.fixed
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}