# $Id: PKGBUILD 119211 2011-04-11 11:17:04Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-session
pkgver=3.0.0
pkgrel=2
pkgdesc="The GNOME Session Handler"
arch=(i686 x86_64)
license=('GPL' 'LGPL')
depends=('upower' 'gtk3' 'gconf' 'startup-notification' 'hicolor-icon-theme'
         'libxtst' 'polkit-gnome' 'libgl' 'librsvg' 'gsettings-desktop-schemas'
         'consolekit' 'libsm' 'dconf')
makedepends=('intltool' 'mesa' 'xtrans')
options=('!emptydirs')
install=gnome-session.install
url="http://www.gnome.org"
groups=('gnome')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('687f2f1daeae3614c36724c7d0f8a5a2eed61e941b11bc3b0f1b156293e51024')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/gnome-session \
      --disable-schemas-compile
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}