# $Id: PKGBUILD 139037 2011-09-28 19:32:57Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: onestep_ua <onestep@ukr.net>

pkgname=polkit-gnome
pkgver=0.103
pkgrel=1
pkgdesc="PolicyKit integration for the GNOME desktop"
arch=('i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/PolicyKit"
license=('LGPL')
depends=('polkit' 'gtk3')
makedepends=('intltool' 'gobject-introspection')
options=(!libtool)
source=(http://download.gnome.org/sources/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz
        polkit-gnome-authentication-agent-1.desktop)
sha256sums=('e12712010c76dd7031f83d932253c53940821f5e47303b02fd70d66062ce396b'
            'ad19e73ae8eba00a8f66bd9afd3e0e1fd7ca22f716e29b97f097d9c01711e0de')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/polkit-gnome \
      --disable-static
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/polkit-gnome-authentication-agent-1.desktop" \
      "${pkgdir}/etc/xdg/autostart/polkit-gnome-authentication-agent-1.desktop"
}