# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

_pkgname=asm
pkgname=java-asm
pkgver=3.3.1
pkgrel=1
pkgdesc="An all purpose Java bytecode manipulation and analysis framework."
arch=('any')
url="http://asm.ow2.org/"
license=('custom:BSD3')
depends=('java-runtime')
source=("http://download.forge.objectweb.org/$_pkgname/$_pkgname-$pkgver.tar.gz")

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  rm examples/jasmin/test/jasmin.jar
  rm cobertura.ser # This is just precompiled for convenience

  echo 'paths.configured /lts' >> build.config
  echo 'test.paths.configured /lts' >> build.config
  ant dist
}

# Tests have more dependencies, and I can't be bothered to package them.
#check() {
#  cd "$srcdir/$_pkgname-$pkgver"
#  ant test
#}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  cd output/dist
  
  install -d "$pkgdir/usr/share/doc/$pkgname"
  cp -r doc/javadoc/user "$pkgdir/usr/share/doc/$pkgname/javadoc"
  cp -r examples         "$pkgdir/usr/share/doc/$pkgname/examples"
  
  install -d "$pkgdir/usr/share/java/$_pkgname"
  cp -r lib/* "$pkgdir/usr/share/java/$_pkgname"
}

md5sums=('433024df8176f09922646316e415631c')