# $Id: pkgbuild-mode.el,v 1.23 2007/10/20 16:02:14 juergen Exp $
# Maintainer: Joshua Ismael Haase Hernandez <joshpar@stravy>
pkgbase='viennarna'
pkgname=('viennarna' 'python2-viennarna')
pkgver=1.8.5
pkgrel=1
pkgdesc="RNA Secondary Structure Prediction and Comparison"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.tbi.univie.ac.at/RNA/"
makedepends=('python2' 'swig')
license=('Custom:BSD3')
source=("setup.py"
        "http://www.tbi.univie.ac.at/RNA/ViennaRNA-${pkgver}.tar.gz")
md5sums=('d006ef9bb878aea6c184afa89986788e'
         'cd70d63cc1be928a5f0973bd6c211e96')

build() {
  cd "$srcdir/ViennaRNA-$pkgver"
  ./configure --prefix=/usr --without-forester
  make
}

package_viennarna() {
  cd "$srcdir/ViennaRNA-$pkgver"
  make DESTDIR="$pkgdir/" install
}

package_python2-viennarna() {
  depends=('python2')
  options=(!emptydirs)

  mkdir -p "$srcdir/ViennaRNA-$pkgver/Python"
  cp -r $srcdir/ViennaRNA-$pkgver/Perl/*.i "$srcdir/setup.py" \
    "$srcdir/ViennaRNA-$pkgver/Python"

  cd "$srcdir/ViennaRNA-$pkgver/Python"

  swig -python RNA.i

  python2 setup.py install --root="$pkgdir/" --optimize=1

}