blob: 33c3510e2f47e06a2089a944e5ff2f80692e10ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# $Id: PKGBUILD 104197 2014-01-16 16:38:43Z flexiondotorg $
# Maintainer : Martin Wimpress <code@flexion.org>
pkgbase=mate-media
pkgname=("${pkgbase}-pulseaudio" "${pkgbase}-gstreamer")
pkgver=1.6.1
pkgrel=1
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gstreamer0.10-base-plugins' 'gtk2' 'libcanberra-pulse' 'libunique'
'mate-desktop' 'mate-window-manager' 'pulseaudio')
makedepends=('mate-common' 'mate-doc-utils' 'mate-panel'
'mate-settings-daemon-gstreamer' 'perl-xml-parser')
options=('!emptydirs')
source=("http://pub.mate-desktop.org/releases/1.6/${pkgbase}-${pkgver}.tar.xz")
sha1sums=('39acbf670a384325b5f68487e62bb1bdddb7d68f')
build() {
cd "${srcdir}"
cp -a ${pkgbase}-${pkgver}{,-gstreamer}
# build for pulseaudio
cd "${srcdir}/${pkgbase}-${pkgver}"
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/${pkgbase} \
--localstatedir=/var \
--enable-pulseaudio \
--disable-gstmix \
--disable-gst-mixer-applet \
--disable-static \
--disable-scrollkeeper
make
# build for gstreamer
cd "${srcdir}/${pkgbase}-${pkgver}-gstreamer"
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/${pkgbase} \
--localstatedir=/var \
--enable-gstmix \
--enable-gst-mixer-applet \
--enable-deprecated \
--disable-pulseaudio \
--disable-static \
--disable-scrollkeeper
make
}
package_mate-media-pulseaudio() {
groups=('mate-extra')
pkgdesc="MATE Media Tools (pulseaudio)"
depends=('libcanberra-pulse' 'libunique' 'mate-desktop' 'mate-window-manager'
'pulseaudio')
conflicts=("${pkgbase}-gstreamer" 'mate-settings-daemon-gstreamer')
provides=("${pkgbase}")
replaces=("${pkgbase}")
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
package_mate-media-gstreamer() {
pkgdesc="MATE Media Tools (GStreamer)"
depends=('gstreamer0.10-base-plugins' 'gtk2' 'libcanberra' 'mate-desktop'
'mate-window-manager')
optdepends=('mate-panel: Volume control for the panel')
conflicts=("${pkgbase}-pulseaudio" 'mate-settings-daemon-pulseaudio')
provides=("${pkgbase}")
install=${pkgbase}-gstreamer.install
cd "${srcdir}/${pkgbase}-${pkgver}-gstreamer"
make DESTDIR="${pkgdir}" install
}
|