blob: 78531b5956dfa3e037bc945c00e5bbe08802c4b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 90406 2013-05-12 08:49:01Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
pkgname=qingy
pkgver=1.0.0
pkgrel=8
pkgdesc="A DirectFB getty replacement"
arch=('i686' 'x86_64' 'mips64el')
url="http://qingy.sourceforge.net/"
license=('GPL')
depends=('directfb' 'openssl' 'libxss')
makedepends=('emacs')
backup=('etc/pam.d/qingy' 'etc/logrotate.d/qingy' 'etc/qingy/settings' 'etc/qingy/welcomes')
options=('!libtool')
install=qingy.install
source=(http://downloads.sourceforge.net/sourceforge/qingy/${pkgname}-${pkgver}.tar.bz2 \
qingy.logrotate qingy@.service)
sha1sums=('22ee505e935bf7ddcbd33e23f754a5a1ca082c81'
'21676cf0b71334c666f7b3e4f3d8b4f319266c81'
'43a6f1cee03ffa598a77cb3c333cb1e8c63b4a2c')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's|/lib/security/||' media/pam/default/qingy
XFREE=/usr/bin/Xorg XINIT=/usr/bin/xinit \
./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc \
--enable-emacs --disable-optimizations --disable-static
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -D -m644 "${srcdir}/qingy.logrotate" "${pkgdir}/etc/logrotate.d/qingy"
install -D -m644 "${srcdir}/qingy@.service" "${pkgdir}/usr/lib/systemd/system/qingy@.service"
}
|
