blob: e9bb21b92dafd32a5325e454eab7e92900a5ed5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 51984 2011-07-18 20:42:27Z rvanharen $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Dmitry N. Shilov <stormblast@land.ru>
pkgname=sakura
pkgver=2.4.1
pkgrel=1
pkgdesc="A terminal emulator based on GTK and VTE"
arch=('i686' 'x86_64' 'mips64el')
url="http://pleyades.net/david/sakura.php"
license=('GPL')
depends=('vte' 'libxft' 'desktop-file-utils')
makedepends=('cmake')
source=(http://pleyades.net/david/projects/$pkgname/$pkgname-$pkgver.tar.bz2)
install=sakura.install
sha1sums=('43858ba79574b4e9413aefd19131dc21c9c1f575')
build() {
cd $srcdir/${pkgname}-${pkgver}
# Set default font size a bit smaller
sed -i 's|#define DEFAULT_FONT "Bitstream Vera Sans Mono 14"|#define DEFAULT_FONT "Bitstream Vera Sans Mono 10"|g' src/sakura.c
# build & install
cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RELEASE .
make
}
package() {
cd $srcdir/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# extract the keybindings from the installed documentation, rest is only relevant during build time
awk '/^Keybindings/{f="'${pkgdir}'/usr/share/doc/'${pkgname}'/KEYBINDINGS"} f{print > f} /^END/' \
${pkgdir}/usr/share/doc/${pkgname}/INSTALL
rm ${pkgdir}/usr/share/doc/${pkgname}/INSTALL
}
|
