blob: 1b09c3d243b3aa85631693cd1bcb9bad53f7e5a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 156074 2012-04-12 21:13:25Z tomegun $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: onestep_ua <onestep@ukr.net>
pkgname=consolekit
pkgver=0.4.6
pkgrel=2
pkgdesc="A framework for defining and tracking users, login sessions, and seats"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.freedesktop.org/wiki/Software/ConsoleKit"
license=('GPL')
depends=('polkit' 'zlib' 'libx11' 'dbus-glib')
makedepends=('pkgconfig' 'xmlto' 'docbook-xsl')
options=(!libtool)
#source=(http://www.freedesktop.org/software/ConsoleKit/dist/ConsoleKit-$pkgver.tar.bz2
# this has not been released yet, so this is a snapshot
source=(ftp://ftp.archlinux.org/other/${pkgname}/ConsoleKit-${pkgver}.tar.bz2
pam-foreground-compat.ck consolekit.logrotate consolekit.tmpfiles.conf)
build() {
cd "$srcdir/ConsoleKit-$pkgver"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/ConsoleKit \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--enable-pam-module \
--enable-docbook-docs \
--enable-udev-acl
make
}
package() {
cd "$srcdir/ConsoleKit-$pkgver"
make DESTDIR="$pkgdir" install
install -m755 "$srcdir/pam-foreground-compat.ck" "$pkgdir/usr/lib/ConsoleKit/run-session.d/"
# install the logrotate config
install -D -m644 "$srcdir/consolekit.logrotate" "$pkgdir/etc/logrotate.d/consolekit"
install -D -m644 "$srcdir/consolekit.tmpfiles.conf" "$pkgdir/usr/lib/tmpfiles.d/consolekit.conf"
rm -rf "${pkgdir}/var/run"
}
md5sums=('810990b607e338f06a6396c92b8a4a06'
'a8a4de71d9b0549b8143e5f6c2a36fc7'
'6fefa451d9fe2fc6d6269629d3529793'
'8c5a8059db515d40fae1379daf084094')
|
