blob: 26966b96d1976ddee2543494c229c25b4baf363d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id: PKGBUILD 107445 2011-01-25 10:20:52Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Sarah Hay <sarah@archlinux.org>
pkgbase=gnome-python
pkgname=('gnome-python' 'python2-bonobo' 'python2-gconf' 'python2-libgnome' 'python2-gnomecanvas' 'python2-gnomevfs')
pkgver=2.28.1
pkgrel=7
arch=(i686 x86_64 'mips64el')
license=('LGPL')
makedepends=('pygtk' 'pyorbit' 'libgnomeui')
options=('!libtool')
url="http://www.pygtk.org/"
source=(http://ftp.gnome.org/pub/gnome/sources/gnome-python/2.28/gnome-python-${pkgver}.tar.bz2)
sha256sums=('759ce9344cbf89cf7f8449d945822a0c9f317a494f56787782a901e4119b96d8')
build() {
cd "${srcdir}/gnome-python-${pkgver}"
PYTHON=python2 ./configure --prefix=/usr
make
}
package_gnome-python() {
pkgdesc="PyGNOME Python extension module"
depends=('python2-bonobo' 'python2-gconf' 'python2-libgnome' 'python2-gnomecanvas' 'python2-gnomevfs')
cd "${srcdir}/gnome-python-${pkgver}"
make install-pkgconfigDATA DESTDIR="${pkgdir}"
}
package_python2-bonobo(){
pkgdesc="Python bindings for interacting with Bonobo"
depends=('pygtk' 'libbonoboui' 'pyorbit' 'python2-gnomecanvas')
cd "${srcdir}/gnome-python-${pkgver}"
make -C bonobo install DESTDIR="${pkgdir}"
}
package_python2-gconf(){
pkgdesc="Python bindings for interacting with GConf"
depends=('pygtk' 'gconf')
cd "${srcdir}/gnome-python-${pkgver}"
make -C gconf install DESTDIR="${pkgdir}"
}
package_python2-libgnome() {
pkgdesc="Python bindings for libgnome"
depends=('pygtk' 'libgnomeui' 'python2-gnomevfs' 'python2-gnomecanvas' 'python2-bonobo')
cd "${srcdir}/gnome-python-${pkgver}"
make -C gnome install DESTDIR="${pkgdir}"
}
package_python2-gnomecanvas() {
pkgdesc="Python bindings for the GNOME Canvas"
depends=('pygtk' 'libgnomecanvas')
cd "${srcdir}/gnome-python-${pkgver}"
make -C gnomecanvas install DESTDIR="${pkgdir}"
}
package_python2-gnomevfs() {
pkgdesc="Python bindings for interacting with gnome-vfs"
depends=('python2' 'libbonobo' 'gnome-vfs')
cd "${srcdir}/gnome-python-${pkgver}"
make -C gnomevfs install DESTDIR="${pkgdir}"
}
|
