blob: c8ad827ae9d2085610872977ea204dd2da782852 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 166940 2012-09-22 20:23:08Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
# Contributor: JaDa <jada@archlinux.us>
# Contributor: Joaquim Pedro <osmano807@gmail.com>
# Contributor: Jan Rüegg <rggjan@gmail.com>
pkgname=gperftools
pkgver=2.0
pkgrel=4
pkgdesc="Fast, multi-threaded malloc() and nifty performance analysis tools"
arch=('i686' 'x86_64')
url="http://code.google.com/p/gperftools/"
license=('BSD')
depends=('perl')
optdepends=('graphviz: pprof graph generation'
'gv: pprof postscript generation')
options=('!libtool')
source=("http://$pkgname.googlecode.com/files/$pkgname-$pkgver.tar.gz")
sha256sums=('7de3dd91f018825b1e7d332af1edace15c6211f430186febede1835069861080')
build() {
cd "$pkgname-$pkgver"
# fix for glibc 2.16
sed -i 's:siginfo_t:siginfo:' src/base/linuxthreads.cc
./configure --prefix=/usr --enable-frame-pointers
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
