blob: e67d63520a52c5782feb057e6fb590569d34e6da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 122323 2011-05-03 20:18:27Z stephane $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=gtk2
pkgname=('gtk2' 'gtk-update-icon-cache')
pkgver=2.24.4
pkgrel=2
arch=('i686' 'x86_64')
url="http://www.gtk.org/"
makedepends=('atk' 'pango' 'libxcursor' 'libxinerama' 'libxrandr' 'libxi' 'libxcomposite' 'libxdamage' 'krb5' 'gnutls'
'shared-mime-info' 'cairo' 'libcups' 'gdk-pixbuf2' 'gobject-introspection')
options=('!libtool' '!docs')
license=('LGPL')
source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/2.24/gtk+-${pkgver}.tar.bz2
xid-collision-debug.patch)
sha256sums=('7d3033ad83647079977466d3e8f1a7533f47abd5cc693f01b8797ff43dd407a5'
'd758bb93e59df15a4ea7732cf984d1c3c19dff67c94b957575efea132b8fe558')
build() {
cd "${srcdir}/gtk+-${pkgver}"
patch -Np1 -i "${srcdir}/xid-collision-debug.patch"
CXX=/bin/false ./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-xinput=yes
make
}
package_gtk2() {
pkgdesc="The GTK+ Toolkit (v2)"
install=gtk2.install
depends=('atk' 'pango' 'libxcursor' 'libxinerama' 'libxrandr' 'libxi' 'libxcomposite' 'libxdamage' 'krb5' 'gnutls' 'shared-mime-info' 'cairo' 'libcups' 'gtk-update-icon-cache')
backup=(etc/gtk-2.0/gtkrc)
cd "${srcdir}/gtk+-${pkgver}"
make DESTDIR="${pkgdir}" install
sed -i "s#env python#env python2#" $pkgdir/usr/bin/gtk-builder-convert
echo 'gtk-fallback-icon-theme = "gnome"' > "${pkgdir}/etc/gtk-2.0/gtkrc"
#split this out to use with gtk3 too
rm ${pkgdir}/usr/bin/gtk-update-icon-cache
}
package_gtk-update-icon-cache() {
pkgdesc="The GTK+ update icon cache tool"
depends=('gdk-pixbuf2')
cd "${srcdir}/gtk+-${pkgver}/gtk"
install -D -m755 gtk-update-icon-cache ${pkgdir}/usr/bin/gtk-update-icon-cache
}
|
