blob: 3e808f48fd267dc0353a0c82642f00a8d5f6f976 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 171085 2012-11-16 14:51:57Z allan $
# Maintainer:
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Jason Chu <jason@archlinux.org>
# Contributor: Juergen Hoetzel <jason@archlinux.org>
pkgname=kismet
pkgver=2011_03_R2
_realver="${pkgver//_/-}"
pkgrel=5
pkgdesc="802.11 layer2 wireless network detector, sniffer, and intrusion detection system"
arch=('i686' 'x86_64')
url="http://www.kismetwireless.net/"
license=('GPL')
depends=('libcap' 'libnl1' 'pcre' 'ncurses' 'libpcap>=1.0.0' 'bluez' 'openssl' 'libusb-compat')
optdepends=('gpsd: log coordinates of detected networks'
'wireshark-cli: provide OUI files used to determine device manufacturer'
'wireshark-cli: mergecap, to merge multiple capture files'
'sox: provide the default kismet sound playback binary'
'festival: text-to-speech support'
'flite: alternative/lightweight text-to-speech support'
'ruby: ruby interface')
backup=('etc/kismet.conf' 'etc/kismet_drone.conf')
install=kismet.install
changelog=kismet.changelog
source=("http://www.kismetwireless.net/code/${pkgname}-${_realver}.tar.gz"{,.asc})
md5sums=('8bf077e8111e6dc8c12cadefdf40aadd'
'500deff918ede6d0bc392a0419322833')
build() {
cd "${srcdir}/${pkgname}-${_realver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var
make dep
make
# Include plugins bundled with kismet
make plugins
}
package() {
cd "${srcdir}/${pkgname}-${_realver}"
# Install kismet
make DESTDIR="$pkgdir" install
# Install plugins
make plugins-install DESTDIR="$pkgdir"
# the README is very comprehensive, a good idea to include it
install -D -m 644 "${srcdir}/kismet-${_realver}/README" "${pkgdir}/usr/share/kismet/README"
# Our own suid-install, first half (see kismet.install)
install -o "root" -g "root" -m 4550 kismet_capture "${pkgdir}/usr/bin/"
}
|
