blob: d8010d675766d8ea9766b67b7a3dbe57c0be1b33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 134393 2011-08-03 15:08:59Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
pkgname=mercurial
pkgver=1.9.1
pkgrel=1
pkgdesc="A scalable distributed SCM tool"
arch=('i686' 'x86_64' 'mips64el')
url="http://mercurial.selenic.com/"
license=('GPL')
depends=('python2')
optdepends=('tk: for the hgk GUI')
backup=('etc/mercurial/hgrc')
source=(http://mercurial.selenic.com/release/${pkgname}-${pkgver}.tar.gz
mercurial.profile)
md5sums=('601990cc58af8316af4e1ea63e19d1be'
'43e1d36564d4c7fbe9a091d3ea370a44')
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python2 setup.py install --root="${pkgdir}/" --optimize=1
sed -i -e 's#env python#env python2#' \
"${pkgdir}"/usr/lib/python2.7/site-packages/mercurial/lsprof.py
install -d ${pkgdir}/usr/share/man/{man1,man5}
install -m644 doc/hg.1 "${pkgdir}/usr/share/man/man1"
install -m644 doc/{hgrc.5,hgignore.5} "${pkgdir}/usr/share/man/man5"
install -m755 contrib/hgk "${pkgdir}/usr/bin"
install -m644 -D contrib/zsh_completion "${pkgdir}/usr/share/zsh/site-functions/_hg"
install -m644 -D contrib/bash_completion "${pkgdir}/etc/bash_completion.d/hg"
install -d "${pkgdir}/usr/share/emacs/site-lisp"
install -m644 contrib/{mq.el,mercurial.el} "${pkgdir}/usr/share/emacs/site-lisp"
vimpath="${pkgdir}/usr/share/vim/vimfiles"
install -Dm644 contrib/vim/HGAnnotate.vim "${vimpath}/syntax/HGAnnotate.vim"
# set some variables
install -m755 -d ${pkgdir}/etc/profile.d
install -m755 ${srcdir}/mercurial.profile "${pkgdir}/etc/profile.d/mercurial.sh"
# install configuration file
install -m755 -d ${pkgdir}/etc/mercurial
install -m644 contrib/sample.hgrc "${pkgdir}/etc/mercurial/hgrc"
}
|
