blob: 85cbf0fcf6b429d61789a29236aea602ed181b61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 1214 2009-08-14 01:36:33Z dgriffiths $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=physfs
pkgver=2.0.3
pkgrel=1
pkgdesc="A library to provide abstract access to various archives"
arch=('i686' 'x86_64')
url="http://icculus.org/physfs/"
license=('ZLIB')
depends=('zlib')
makedepends=('cmake' 'doxygen')
source=(http://icculus.org/physfs/downloads/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('327308c777009a41bbabb9159b18c4c0ac069537')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
cmake . -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPHYSFS_BUILD_TEST=OFF -DPHYSFS_BUILD_WX_TEST=OFF
make all docs
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}"/usr/share/{doc/physfs,man/man3}
install -m644 docs/html/* "${pkgdir}/usr/share/doc/physfs"
install -m644 docs/man/man3/* "${pkgdir}/usr/share/man/man3"
for i in author Deinit description extension Free Init major Malloc minor opaque patch Realloc url ; do
mv "${pkgdir}/usr/share/man/man3/$i.3" "${pkgdir}/usr/share/man/man3/PHYSFS_$i.3"
done
install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
