blob: fe18cff2878440f085ce28d9844848121239ed1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 125918 2011-05-31 21:19:50Z andrea $
# Maintainer:
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Jeramy Rutley <jrutley@gmail.com>
pkgbase=ruby
pkgname=('ruby' 'ruby-docs')
pkgver=1.9.2_p180
pkgrel=2
pkgdesc="An object-oriented language for quick and easy programming"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.ruby-lang.org/en/"
license=('custom')
makedepends=('openssl' 'tk' 'libffi' 'doxygen' 'graphviz')
options=('!emptydirs')
source=("ftp://ftp.ruby-lang.org/pub/${pkgbase}/1.9/${pkgbase}-${pkgver//_/-}.tar.bz2")
md5sums=('68510eeb7511c403b91fe5476f250538')
sha1sums=('10824b44c8060c7b9b5afc0b3519a1e9f02f7fe5')
build() {
cd "${srcdir}/${pkgbase}-${pkgver//_/-}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--enable-shared \
--enable-pthread \
--disable-rpath
make
}
package_ruby() {
depends=('openssl' 'libffi')
provides=('rubygems' 'rake')
conflicts=('rake')
optdepends=('tk: for Ruby/TK')
cd "${srcdir}/${pkgbase}-${pkgver//_/-}"
make DESTDIR="${pkgdir}" install-nodoc
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_ruby-docs() {
pkgdesc="Documentation files for ruby"
depends=('ruby')
cd "${srcdir}/${pkgbase}-${pkgver//_/-}"
make -j1 DESTDIR="${pkgdir}" install-doc install-capi
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
