blob: 4b145440667caf5b2f9f1b2886ef8e5a914306b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 164370 2012-07-31 19:43:25Z eric $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=upower
pkgver=0.9.17
pkgrel=2
pkgdesc="Abstraction for enumerating power devices, listening to device events and querying history and statistics"
arch=('i686' 'x86_64')
url="http://upower.freedesktop.org"
license=('GPL')
depends=('systemd-tools' 'libusb' 'polkit' 'pm-utils' 'dbus-glib' 'libimobiledevice')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection')
options=('!libtool')
source=($url/releases/$pkgname-$pkgver.tar.xz)
build() {
cd "$pkgname-$pkgver"
# put udev files in /usr/lib
sed -i "/slashlibdir=/s#/lib#/usr/lib#" configure
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/upower \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--disable-static
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
md5sums=('9ef7fc8ec438542f014f3a34552822aa')
|
