1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
|
# $Id: PKGBUILD 125313 2011-05-25 20:09:55Z heftig $
# Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Maintainer: tobias [ tobias at archlinux org ]
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>
pkgbase=vim
pkgname=(vim gvim vim-runtime)
_topver=7.3
_patchlevel=206
pkgver=${_topver}.${_patchlevel}
__hgrev=e9538cfd0d9c
pkgrel=1
arch=('i686' 'x86_64')
license=('custom:vim')
url="http://www.vim.org"
makedepends=('gpm' 'perl' 'python2>=2.7.1' 'ruby' 'libxt' 'desktop-file-utils' 'gtk2'
'gettext' 'pkgconfig' 'mercurial' 'rsync' 'sed')
source=(pythoncomplete.vim::http://www.vim.org/scripts/download_script.php\?src_id=10872
vimrc archlinux.vim gvim.desktop)
md5sums=('6e7adfbd5d26c1d161030ec203a7f243'
'e57777374891063b9ca48a1fe392ac05'
'10353a61aadc3f276692d0e17db1478e'
'4b83e5fe0e534c53daaba91dd1cd4cbb')
__hgroot='http://vim.googlecode.com/hg/'
__hgrepo='vim'
__hgbranch='default'
_versiondir="vim${_topver//./}"
##### Build #####
build() {
cd ${srcdir}
msg2 'Checking out source from Mercurial...'
if [[ -d ${__hgrepo} ]]; then
cd ${__hgrepo}
hg pull -b ${__hgbranch}|| warning 'hg pull failed!'
hg update -r ${__hgrev}
else
hg clone -b ${__hgbranch} -u ${__hgrev} "${__hgroot}${__hgrepo}" ${__hgrepo}
cd ${__hgrepo}
fi
if (( $(hg id -n) < $(hg id -nr ${__hgbranch}) )); then
warning 'You are not building the latest revision!'
warning "Consider updating __hgrev to $(hg id -r ${__hgbranch})."
sleep 10
fi
cd ..
rm -rf vim-build gvim-build
rsync -a --exclude='.hg/' ${__hgrepo}/ vim-build
msg2 'Patching...'
# define the place for the global (g)vimrc file (set to /etc/vimrc)
sed -i 's|^.*\(#define SYS_.*VIMRC_FILE.*"\) .*$|\1|' \
vim-build/src/feature.h
sed -i 's|^.*\(#define VIMRC_FILE.*"\) .*$|\1|' \
vim-build/src/feature.h
# fix python name
sed -i -e 's|vi_cv_path_python, python|vi_cv_path_python, python2|' \
vim-build/src/configure.in
(cd vim-build/src && autoconf)
msg2 'Building...'
cp -a vim-build gvim-build
cd ${srcdir}/vim-build
./configure --prefix=/usr --localstatedir=/var/lib/vim \
--mandir=/usr/share/man --with-compiledby=ArchLinux \
--with-features=big --enable-gpm --enable-acl --with-x=no \
--disable-gui --enable-multibyte --enable-cscope \
--disable-netbeans --enable-perlinterp --disable-pythoninterp \
--disable-rubyinterp
make
cd ${srcdir}/gvim-build
./configure --prefix=/usr --localstatedir=/var/lib/vim \
--mandir=/usr/share/man --with-compiledby=ArchLinux \
--with-features=big --enable-gpm --enable-acl --with-x=yes \
--enable-gui=gtk2 --enable-multibyte --enable-cscope \
--enable-netbeans --enable-perlinterp --enable-pythoninterp \
--enable-rubyinterp
make
}
##### Packaging #####
package_vim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'perl')
conflicts=('gvim')
cd ${srcdir}/vim-build
make -j1 VIMRCLOC=/etc DESTDIR=${pkgdir} install
# provided by (n)vi in core
rm ${pkgdir}/usr/bin/{ex,view}
# delete some manpages
find ${pkgdir}/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd ${_mandir}
rm -f ex.1 view.1 # provided by (n)vi
rm -f evim.1 # this does not make sense if we have no GUI
done
# Runtime provided by runtime package
rm -r ${pkgdir}/usr/share/vim
# license
install -dm755 ${pkgdir}/usr/share/licenses/vim
ln -s /usr/share/vim/${_versiondir}/doc/uganda.txt \
${pkgdir}/usr/share/licenses/vim/license.txt
}
package_gvim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor (with advanced features, such as a GUI)'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'perl' 'python2>=2.7.1' 'ruby' 'libxt'
'desktop-file-utils' 'gtk2')
provides=("vim=${pkgver}-${pkgrel}")
conflicts=('vim')
install=gvim.install
cd ${srcdir}/gvim-build
make -j1 VIMRCLOC=/etc DESTDIR=${pkgdir} install
# provided by (n)vi in core
rm ${pkgdir}/usr/bin/{ex,view}
# delete some manpages
find ${pkgdir}/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd ${_mandir}
rm -f ex.1 view.1 # provided by (n)vi
done
# Move the runtime for later packaging
mv ${pkgdir}/usr/share/vim ${srcdir}/runtime-install
# freedesktop links
install -Dm644 ${srcdir}/gvim.desktop \
${pkgdir}/usr/share/applications/gvim.desktop
install -Dm644 runtime/vim48x48.png ${pkgdir}/usr/share/pixmaps/gvim.png
# license
install -dm755 ${pkgdir}/usr/share/licenses/gvim
ln -s /usr/share/vim/${_versiondir}/doc/uganda.txt \
${pkgdir}/usr/share/licenses/gvim/license.txt
}
package_vim-runtime() {
pkgdesc='Runtime for vim and gvim'
backup=(etc/vimrc)
# Install the runtime split from gvim
install -dm755 ${pkgdir}/usr/share
mv ${srcdir}/runtime-install ${pkgdir}/usr/share/vim
# Don't forget logtalk.dict
install -Dm644 ${srcdir}/gvim-build/runtime/ftplugin/logtalk.dict \
${pkgdir}/usr/share/vim/${_versiondir}/ftplugin/logtalk.dict
# fix FS#17216
sed -i 's|messages,/var|messages,/var/log/messages.log,/var|' \
${pkgdir}/usr/share/vim/${_versiondir}/filetype.vim
# patch filetype.vim for better handling of pacman related files
sed -i "s/rpmsave/pacsave/;s/rpmnew/pacnew/;s/,\*\.ebuild/\0,PKGBUILD*,*.install/" \
${pkgdir}/usr/share/vim/${_versiondir}/filetype.vim
sed -i "/find the end/,+3{s/changelog_date_entry_search/changelog_date_end_entry_search/}" \
${pkgdir}/usr/share/vim/${_versiondir}/ftplugin/changelog.vim
# make Aaron happy
install -Dm644 ${srcdir}/pythoncomplete.vim \
${pkgdir}/usr/share/vim/${_versiondir}/autoload/pythoncomplete.vim
# rc files
install -Dm644 ${srcdir}/vimrc ${pkgdir}/etc/vimrc
install -Dm644 ${srcdir}/archlinux.vim \
${pkgdir}/usr/share/vim/vimfiles/archlinux.vim
# license
install -dm755 ${pkgdir}/usr/share/licenses/vim-runtime
ln -s /usr/share/vim/${_versiondir}/doc/uganda.txt \
${pkgdir}/usr/share/licenses/vim-runtime/license.txt
}
# vim:set sw=2 sts=2 et:
|
