blob: fb0b2b52544ac7ed58462a7313c52493ad38e2f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 169970 2012-10-30 22:59:21Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=vte3
pkgname=(vte3 vte-common)
pkgver=0.34.1
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
arch=('i686' 'x86_64' 'mips64el')
license=('LGPL')
options=('!libtool' '!emptydirs')
makedepends=('intltool' 'gobject-introspection' 'gtk3')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/GNOME/sources/vte/${pkgver%.*}/vte-$pkgver.tar.xz)
sha256sums=('06b78824875545ced8ebaff111b656d0b4ed370f46a4b609f43f88a0ee908f08')
build() {
cd "vte-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/vte \
--localstatedir=/var --disable-static \
--enable-introspection
make
}
package_vte3(){
depends=('gtk3' 'vte-common')
cd "vte-$pkgver"
make DESTDIR="$pkgdir" install
rm "$pkgdir"/usr/lib/vte/gnome-pty-helper
}
package_vte-common() {
pkgdesc="Common files used by vte and vte3"
depends=('glibc')
cd "vte-$pkgver"
make -C gnome-pty-helper DESTDIR="$pkgdir" install
}
|
