blob: 87f61741718f980db5c886bc8eb82b4339fd3528 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 165091 2012-08-10 09:03:30Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
pkgname=wget
pkgver=1.14
pkgrel=1
pkgdesc="A network utility to retrieve files from the Web"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/wget/wget.html"
license=('GPL3')
depends=('glibc' 'openssl')
optdepends=('ca-certificates: HTTPS downloads')
backup=('etc/wgetrc')
install=wget.install
source=(ftp://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.xz{,.sig})
md5sums=('316f6f59292c9098ad81fd54f658c579'
'3e121933d69f32fa58776bff76bcebd0')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Note : We do not build with --enable-nls, because there is a bug in wget causing
# international domain names to be not properly converted to punycode if
# the current locale is a UTF-8 one
# See : http://lists.gnu.org/archive/html/bug-wget/2011-02/msg00026.html
./configure -with-ssl=openssl --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
cat >> "$pkgdir/etc/wgetrc" <<EOF
# default root certs location
ca_certificate=/etc/ssl/certs/ca-certificates.crt
EOF
# remove IRI option from wgetrc as it does not work (see above)
sed -i '118,120d' $pkgdir/etc/wgetrc
}
|
