blob: 86a31d841f3adc8ed12a9943ec15758f3d7a8354 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 143279 2011-11-24 16:13:15Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=kdelibs
pkgver=4.7.80
pkgrel=1
pkgdesc="KDE Core Libraries"
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
depends=('strigi' 'attica' 'libxss' 'xz' 'soprano' 'krb5' 'grantlee'
'shared-desktop-ontologies' 'qca' 'libdbusmenu-qt' 'polkit-qt'
'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr' 'docbook-xsl'
'phonon' 'upower' 'udisks' 'libxcursor')
makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'hspell')
replaces=('kdelibs-experimental')
install=${pkgname}.install
source=("http://download.kde.org/unstable/${pkgver}/src/${pkgname}-${pkgver}.tar.bz2"
'kde-applications-menu.patch' 'archlinux-menu.patch')
sha1sums=('0dac96f3d7445bde8e2e7066986ca5656d441b02'
'86ee8c8660f19de8141ac99cd6943964d97a1ed7'
'63a850ab4196b9d06934f2b4a13acd9f7739bc67')
build() {
cd "${srcdir}"/${pkgname}-${pkgver}
# avoid file conflict with gnome-menus
patch -p1 -i "${srcdir}"/kde-applications-menu.patch
# add Archlinux menu entry
patch -p1 -i "${srcdir}"/archlinux-menu.patch
cd "${srcdir}"
mkdir build
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DKDE_DISTRIBUTION_TEXT='Arch Linux' \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSYSCONF_INSTALL_DIR=/etc \
-DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
-DKDE_DEFAULT_HOME='.kde4' \
-DWITH_FAM=OFF
make
}
package() {
cd "${srcdir}"/build
make DESTDIR="${pkgdir}" install
# cert bundle seems to be hardcoded
# link it to the one from ca-certificates
rm -f "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
ln -sf /etc/ssl/certs/ca-certificates.crt "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
}
|
