1 files changed, 51 insertions, 0 deletions
diff --git a/community/dia/PKGBUILD b/community/dia/PKGBUILD
new file mode 100644
index 000000000..609215664
--- /dev/null
+++ b/community/dia/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 90015 2013-05-06 19:36:39Z foutrelis $
+# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Juergen Hoetzel <juergen@archlinux.org>
+# Contributor: Gregor Ibic <gregor.ibic@intelicom.si>
+
+pkgname=dia
+pkgver=0.97.2
+pkgrel=5
+pkgdesc="A GTK+ based diagram creation program"
+arch=('i686' 'x86_64')
+license=('GPL')
+url="http://live.gnome.org/Dia"
+install=dia.install
+depends=('libxslt' 'desktop-file-utils' 'libart-lgpl' 'gtk2' 'hicolor-icon-theme')
+makedepends=('intltool' 'python2' 'docbook-xsl')
+optdepends=('python2')
+options=('!libtool' 'docs' '!emptydirs')
+source=("ftp://ftp.gnome.org/pub/gnome/sources/${pkgname}/0.97/${pkgname}-${pkgver}.tar.xz"
+	"dia-crash.patch::https://git.gnome.org/browse/dia/patch/?id=213bdfe956bf8fe57c86316f68a09408fef1647e")
+md5sums=('1e1180a513fb567709b09bc19f12105e'
+         '2ad4fcfbfb561930a1d0335cc942a07b')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  export PYTHON=/usr/bin/python2
+  for file in `find -type f -name '*.py'`; do
+      sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_' "$file"
+  done
+  sed -i 's#python2\.1#python2 python2.1#' configure
+  patch -p1 <$srcdir/dia-crash.patch
+
+  ./configure --prefix=/usr \
+    --with-cairo \
+    --with-python \
+    --disable-gnome \
+    --with-hardbooks
+  sed -i 's#SUBDIRS = lib objects plug-ins shapes app bindings samples po sheets data doc tests installer#SUBDIRS = lib objects plug-ins shapes app bindings samples po sheets data tests installer#' Makefile
+  make
+  cd doc
+  make html
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  cd doc
+  make DESTDIR="${pkgdir}" install-html
+  ln -sf ../doc/dia/html "${pkgdir}"/usr/share/dia/help
+}