1 files changed, 46 insertions, 0 deletions
diff --git a/community/mapnik/PKGBUILD b/community/mapnik/PKGBUILD
new file mode 100644
index 000000000..8d572e131
--- /dev/null
+++ b/community/mapnik/PKGBUILD
@@ -0,0 +1,46 @@
+# $Id: PKGBUILD 94032 2013-07-13 12:33:54Z svenstaro $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: David Dent <thewinch@gmail.com>
+# Contributor: orbisvicis <orbisvicis@gmail.com>
+
+pkgname=mapnik
+pkgver=2.2.0
+pkgrel=3
+pkgdesc="Free Toolkit for developing mapping applications. Above all Mapnik is about rendering beautiful maps"
+arch=('i686' 'x86_64')
+url="http://mapnik.org/"
+license=('LGPL')
+depends=('boost-libs' 'icu' 'libpng' 'libjpeg' 'libtiff' 'freetype2'
+	 'libxml2' 'python2' 'proj' 'cairo' 'cairomm' 'pycairo'
+	 'postgresql-libs' 'postgis' 'gdal' 'curl' 'libltdl')
+optdepends=('libxslt:         Web Map Service'
+            'python2-lxml:    Web Map Service'
+            'python-imaging:  Web Map Service'
+            'python-nose:     Web Map Service'
+            'apache:          Web Map Service'
+            'mod_fastcgi:     Web Map Service - or:'
+            'mod_fcgid:       Web Map Service - or:'
+            'mod_wsgi2:       Web Map Service')
+makedepends=('scons' 'boost')
+install="mapnik.install"
+source=("https://github.com/mapnik/mapnik/archive/v$pkgver.tar.gz")
+md5sums=('b837931c7f1a4dc630d8550d3e635036')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  sed -i 's|lib64|lib|g' SConstruct
+  sed -i 's|python|python2|' \
+	utils/performance/mapnik-speed-check \
+	utils/upgrade_map_xml/*.py
+  scons configure \
+    PREFIX="/usr" \
+    INPUT_PLUGINS=all \
+    DESTDIR="$pkgdir"
+  scons $MAKEFLAGS
+}
+
+package(){
+  cd "$srcdir/$pkgname-$pkgver"
+  scons install
+}