1 files changed, 49 insertions, 0 deletions
diff --git a/community/xdebug/PKGBUILD b/community/xdebug/PKGBUILD
new file mode 100644
index 000000000..b6b2cc3e9
--- /dev/null
+++ b/community/xdebug/PKGBUILD
@@ -0,0 +1,49 @@
+# $Id: PKGBUILD 92281 2013-06-03 13:37:54Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Maintainer: Jonathan Wiersma <arch aur at jonw dot org>
+# Contributor: Jonathan Wiersma <arch aur at jonw dot org>
+# Contributor: sracker <smb.sac@gmail.com>
+
+pkgname=xdebug
+pkgver=2.2.3
+pkgrel=1
+pkgdesc="PHP debugging extension"
+arch=('i686' 'x86_64')
+url="http://www.xdebug.org"
+license=('GPL')
+depends=('php')
+install="${pkgname}.install"
+backup=('etc/php/conf.d/xdebug.ini')
+source=(http://www.xdebug.org/files/$pkgname-$pkgver.tgz
+	xdebug-5.2.ini
+	xdebug.ini)
+md5sums=('e49cec9861b45dc0b36eae33bf8a14fa'
+         '6b7fdbbe0bf381bda40e77e29981f439'
+         '68de800943369d4c76bdf7eb35c8463b')
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  phpize
+  ./configure --prefix=/usr --enable-xdebug
+  make
+
+  cd debugclient
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  local PHPVER=`php -r 'echo phpversion();'`
+
+  cd $srcdir/$pkgname-$pkgver/debugclient
+  make DESTDIR=$pkgdir install
+
+  cd $srcdir/$pkgname-$pkgver
+  if [ "$PHPVER" \< "5.3.0" ] ; then
+    install -D -m 744 modules/xdebug.so $pkgdir/usr/lib/php/modules/xdebug.so
+    install -D -m 644 $srcdir/xdebug-5.2.ini $pkgdir/etc/php/conf.d/xdebug.ini
+  else
+    install -D -m 744 modules/xdebug.so $pkgdir/usr/lib/php/modules/xdebug.so
+    install -D -m 644 $srcdir/xdebug.ini $pkgdir/etc/php/conf.d/xdebug.ini
+  fi
+}