1 files changed, 39 insertions, 0 deletions
diff --git a/testing/seahorse/PKGBUILD b/testing/seahorse/PKGBUILD
new file mode 100644
index 000000000..d1591ed7c
--- /dev/null
+++ b/testing/seahorse/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id: PKGBUILD 169156 2012-10-18 19:22:42Z jgc $
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Jan de Groot <jgc@archlinux.org>
+# Contributor: Michel Brabants <michel.linux@tiscali.be>
+
+pkgname=seahorse
+pkgver=3.6.1
+pkgrel=1
+pkgdesc="GNOME application for managing PGP keys."
+arch=(i686 x86_64)
+license=(GPL)
+url="http://projects.gnome.org/seahorse/"
+depends=(gtk3 gcr libsecret libsoup gpgme desktop-file-utils hicolor-icon-theme dconf)
+makedepends=(libldap intltool yelp-tools gobject-introspection openssh libsm)
+optdepends=('openssh: SSH support')
+provides=(x11-ssh-askpass)
+options=('!libtool' '!emptydirs')
+groups=(gnome-extra)
+install=seahorse.install
+source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz
+        seahorse-ssh-askpass.sh)
+sha256sums=('dcdd9681a7896a13a597cf02aa2d6718b5f0ab3b50ed81f8d24b8db296a9214b'
+            '400ea9a6084acc93f1dbd4223b95622bbd48071b763063328efba00de378b68c')
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-ldap --enable-hkp \
+      --disable-schemas-compile
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm755 "$srcdir/seahorse-ssh-askpass.sh" \
+    "$pkgdir/etc/profile.d/seahorse-ssh-askpass.sh"
+}