From 89dd7b5f30d48c708092a71b1c8285090fe91505 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Mon, 28 May 2012 00:02:35 +0000
Subject: Mon May 28 00:02:35 UTC 2012

---
 community-testing/conntrack-tools/PKGBUILD | 53 ++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 community-testing/conntrack-tools/PKGBUILD

(limited to 'community-testing/conntrack-tools/PKGBUILD')

diff --git a/community-testing/conntrack-tools/PKGBUILD b/community-testing/conntrack-tools/PKGBUILD
new file mode 100644
index 000000000..f8c8ba7ef
--- /dev/null
+++ b/community-testing/conntrack-tools/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id: PKGBUILD 71335 2012-05-27 00:50:12Z seblu $
+# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
+# Contributor: Valere Monseur <valere_monseur@hotmail.com>
+# Contributor: Alessandro Sagratini <ale_sagra@hotmail.com>
+# Contributor: Kevin Edmonds <edmondskevin@hotmail.com>
+
+pkgname=conntrack-tools
+pkgver=1.2.0
+pkgrel=1
+pkgdesc='Userspace tools to interact with the Netfilter connection tracking system'
+arch=('i686' 'x86_64')
+url='http://www.netfilter.org/projects/conntrack-tools'
+license=('GPL2')
+depends=('libnetfilter_conntrack' 'libnetfilter_cttimeout')
+backup=('etc/conntrackd.conf' 'etc/conf.d/conntrackd')
+install=$pkgname.install
+source=("http://www.netfilter.org/projects/$pkgname/files/$pkgname-$pkgver.tar.bz2"
+        'conntrackd.rc'
+        'conntrackd.conf'
+        'conntrackd.service'
+        '01-config-file-path.patch'
+        '02-fix-compilation-of-timeout-extension.patch')
+md5sums=('8e20330d6ca3a3f23552aa900b1d467c'
+         '478fe76da0202fcb5249bf65968d1c26'
+         'd3e73e81b54e3e8166d357d434680684'
+         'bd135eaefb47923bb8e8d26f084d3e9d'
+         '411fc0eb97c02595aab69b14c26c1d00'
+         '0144021bbec4d5b496ddd86a7ff7a257')
+
+build() {
+  cd $pkgname-$pkgver
+  for i in "$srcdir"/*.patch; do
+    patch -p1 -i "$i"
+  done
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make
+}
+
+package() {
+  # install binaries
+  pushd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  popd
+  # initscripts & systemd
+  install -D -m 755 conntrackd.rc "$pkgdir/etc/rc.d/conntrackd"
+  install -D -m 644 conntrackd.conf "$pkgdir/etc/conf.d/conntrackd"
+  install -D -m 644 conntrackd.service \
+    "$pkgdir/usr/lib/systemd/system/conntrackd.service"
+  # install empty configuration files
+  install -D -m 644 /dev/null "$pkgdir/etc/conntrackd.conf"
+}
+
+# vim:set ts=2 sw=2 ft=sh et:
-- 
cgit v1.2.3-54-g00ecf