From 76c26b027d797f3671bf0b6c6618eda2496cf88d Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Fri, 15 Jul 2011 23:12:20 +0000
Subject: Fri Jul 15 23:12:20 UTC 2011

---
 community-testing/python-scipy/PKGBUILD            | 83 ++++++++++++++++++++++
 .../python-scipy/python-scipy.changelog            | 49 +++++++++++++
 2 files changed, 132 insertions(+)
 create mode 100644 community-testing/python-scipy/PKGBUILD
 create mode 100644 community-testing/python-scipy/python-scipy.changelog

(limited to 'community-testing/python-scipy')

diff --git a/community-testing/python-scipy/PKGBUILD b/community-testing/python-scipy/PKGBUILD
new file mode 100644
index 000000000..80a97ca82
--- /dev/null
+++ b/community-testing/python-scipy/PKGBUILD
@@ -0,0 +1,83 @@
+# $Id: PKGBUILD 51728 2011-07-13 14:46:12Z tdziedzic $
+# Maintainer: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Maintainer: Ray Rashif <schiv@archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor@gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu@gmail.com>
+
+pkgbase=python-scipy
+_app=scipy
+pkgname=('python-scipy' 'python2-scipy')
+pkgver=0.9.0
+_theapp=$_app-$pkgver
+pkgrel=2
+pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
+arch=('i686' 'x86_64')
+url="http://www.scipy.org/"
+license=('BSD')
+depends=('python-numpy')
+makedepends=('gcc-fortran' 'python2-numpy')
+changelog=$pkgbase.changelog
+source=("http://downloads.sourceforge.net/$_app/$_theapp.tar.gz")
+md5sums=('ebfef6e8e82d15c875a4ee6a46d4e1cd')
+
+build() {
+  unset LDFLAGS
+  unset FFLAGS
+
+  # Compatibility symlinks for current stable numpy
+  #   - no need to patch numpy just for this
+  # see http://projects.scipy.org/numpy/ticket/1749
+  ln -sf /usr/lib/liblapack.so liblapack.cpython-32mu.so
+  ln -sf /usr/lib/libblas.so libblas.cpython-32mu.so
+  export LAPACK="$srcdir"
+  export BLAS="$srcdir"
+
+  # Changing the arithmetic parameter (Thanks to Fabrizio Castellano)
+  sed -i "s/\#define\ UNK\ 1/\#define\ IBMPC\ 1/" \
+    $_theapp/$_app/special/cephes/mconf.h
+
+  # 2 builds
+  cp -r $_theapp $_theapp-py2
+
+  # build for python3
+  cd $_theapp
+  python setup.py config_fc --fcompiler=gnu95 build
+
+  # build for python2
+  cd ../$_theapp-py2
+
+  for file in $(find . -name '*.py' -print); do
+       sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
+       sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
+  done
+
+  python2 setup.py config_fc --fcompiler=gnu95 build
+}
+
+package_python-scipy() {
+  provides=('python3-scipy' 'scipy')
+
+  cd "$srcdir/$_theapp"
+
+  python setup.py config_fc --fcompiler=gnu95 install \
+    --prefix=/usr --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-scipy() {
+  depends=('python2-numpy')
+  conflicts=('python-scipy<0.9.0')
+
+  cd "$srcdir/$_theapp-py2"
+
+  python2 setup.py config_fc --fcompiler=gnu95 install \
+    --prefix=/usr --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/community-testing/python-scipy/python-scipy.changelog b/community-testing/python-scipy/python-scipy.changelog
new file mode 100644
index 000000000..76a3e7f35
--- /dev/null
+++ b/community-testing/python-scipy/python-scipy.changelog
@@ -0,0 +1,49 @@
+2011-07-13 Thomas Dziedzic < gostrc at gmail >
+	* 0.9.0-2:
+	rebuild for python3-numpy to python-numpy rename
+	also, minor PKGBUILD cleanup
+
+2011-04-24 Ray Rashif <schiv@archlinux.org>
+
+	* 0.9.0-1:
+	Couldn't release previous update due to lapack/blas issues
+	See http://mailman.archlinux.org/pipermail/arch-general/2011-April/019677.html
+	Hopefully symlink trick from AUR/python3-scipy fixes that
+
+2011-04-05 Ray Rashif <schiv@archlinux.org>
+
+	* 0.9.0-1:
+	Upstream release
+	SciPy now supports Python 3
+	Package split for python(3), python2
+	PKGBUILD cleanup
+
+2010-07-29  Angel 'angvp' Velasquez <angvp@archlinux.org>
+	* Updated to: 0.8.0
+2009-08-05  Douglas Soares de Andrade  <douglas@archlinux.org>
+
+	* Updated to: 0.7.1
+
+2009-02-11  Douglas Soares de Andrade  <douglas@archlinux.org>
+
+	* Updating for i686: 0.7
+
+2008-12-12  Douglas Soares de Andrade  <douglas@archlinux.org>
+
+	* Updating for i686: 0.7.0 beta 1
+
+2008-11-07  Douglas Soares de Andrade  <douglas@archlinux.org>
+
+	* Updated to svn as scipy 0.6 wont work with python 2.6
+
+2008-02-21  Eric Belanger  <eric@archlinux.org>
+
+	* Added x86_64 arch tag
+	* Added license
+
+2007-10-29  Douglas Soares de Andrade  <dsa@aur.archlinux.org>
+
+	* Changed email
+	* Fixed some problems in the PKGBUILD
+	* Updated to new release - 0.6.0
+
-- 
cgit v1.2.3-54-g00ecf