From 8fbc0076a4827ddc6af92e0b9daa4c4c31450808 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Fri, 19 Jul 2013 01:10:32 -0700
Subject: Fri Jul 19 01:09:18 PDT 2013

---
 community/couchdb/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 community/couchdb/PKGBUILD

(limited to 'community/couchdb/PKGBUILD')

diff --git a/community/couchdb/PKGBUILD b/community/couchdb/PKGBUILD
new file mode 100644
index 000000000..9ea90c437
--- /dev/null
+++ b/community/couchdb/PKGBUILD
@@ -0,0 +1,48 @@
+# $Id: PKGBUILD 93137 2013-06-25 15:46:03Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Vitaliy Berdinskikh ur6lad[at]i.ua
+# Contributor: Michael Fellinger <m.fellinger@gmail.com>
+
+pkgname=couchdb
+pkgver=1.4.0pre
+pkgrel=1
+pkgdesc="A document-oriented database that can be queried and indexed in a MapReduce fashion using JSON"
+arch=('i686' 'x86_64')
+url="http://couchdb.apache.org"
+license=('APACHE')
+depends=('icu' 'erlang-nox' 'js185' 'openssl' 'curl')
+makedepends=('autoconf-archive' 'git')
+install=couchdb.install
+options=('!libtool')
+backup=('etc/couchdb/local.ini'
+	'etc/conf.d/couchdb'
+	'etc/logrotate.d/couchdb')
+#source=("http://www.sai.msu.su/apache/couchdb/source/$pkgver/apache-couchdb-$pkgver.tar.gz"{,.asc}
+source=("git://github.com/apache/couchdb.git#commit=8d7ab8b18dd20f8785e69f4420c6f93a2edbfa60"
+	"couchdb.service"
+	"couchdb.tmpfiles")
+md5sums=('SKIP'
+         '8914a7ffc6745f94106d96206709acb4'
+         '1e254ebe32eeb061be64193bafa35dbf')
+
+build() {
+  cd "$srcdir/couchdb"
+  ./bootstrap
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var
+  make
+}
+
+package() {
+  cd "$srcdir/couchdb"
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 etc/default/couchdb $pkgdir/etc/conf.d/couchdb
+  sed -i 's|\(COUCHDB_OPTIONS=\)|\1"-p /var/run/couchdb/couchdb.pid"|' $pkgdir/etc/conf.d/couchdb
+
+  rm -rf $pkgdir/etc/default/ $pkgdir/var/run
+
+  install -Dm0644 $srcdir/$pkgname.service $pkgdir/usr/lib/systemd/system/$pkgname.service
+  install -Dm0644 $srcdir/$pkgname.tmpfiles $pkgdir/usr/lib/tmpfiles.d/$pkgname.conf
+}
-- 
cgit v1.2.3-54-g00ecf