From d7918d0226da2805ff09c48963d2c79e1327c630 Mon Sep 17 00:00:00 2001
From: Nicolás Reynolds <fauno@endefensadelsl.org>
Date: Mon, 5 May 2014 04:02:14 +0000
Subject: Mon May  5 03:56:02 UTC 2014

---
 community/haskell-mtl/PKGBUILD            | 50 +++++++++++++++++++++++++++++++
 community/haskell-mtl/haskell-mtl.install | 35 ++++++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 community/haskell-mtl/PKGBUILD
 create mode 100644 community/haskell-mtl/haskell-mtl.install

(limited to 'community/haskell-mtl')

diff --git a/community/haskell-mtl/PKGBUILD b/community/haskell-mtl/PKGBUILD
new file mode 100644
index 000000000..fb3c0f4d0
--- /dev/null
+++ b/community/haskell-mtl/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Thomas Dziedzic <gostrc@gmail.com>
+
+_hkgname=mtl
+pkgname=haskell-mtl
+pkgver=2.1.3.1
+pkgrel=2
+pkgdesc="Monad classes, using functional dependencies"
+url="http://hackage.haskell.org/package/${_hkgname}"
+license=('custom:BSD3')
+arch=('i686' 'x86_64')
+options=('staticlibs')
+depends=('ghc=7.8.2-2' 'sh')
+source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+install=${pkgname}.install
+md5sums=('8f3927677bf3e0efb6fcce08b1be2eac')
+
+build() {
+  cd ${_hkgname}-${pkgver}
+
+  runhaskell Setup configure -O -p \
+    --enable-split-objs \
+    --enable-shared \
+    --prefix=/usr \
+    --docdir=/usr/share/doc/${pkgname} \
+    --libsubdir=\$compiler/site-local/\$pkgid
+
+  runhaskell Setup build
+
+  runhaskell Setup haddock
+
+  runhaskell Setup register   --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd ${_hkgname}-${pkgver}
+
+  install -D -m744 register.sh   ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
+  install    -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
+
+  install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
+  ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
+
+  runhaskell Setup copy --destdir=${pkgdir}
+
+  install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+  rm -f ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
+}
+
diff --git a/community/haskell-mtl/haskell-mtl.install b/community/haskell-mtl/haskell-mtl.install
new file mode 100644
index 000000000..17c40da11
--- /dev/null
+++ b/community/haskell-mtl/haskell-mtl.install
@@ -0,0 +1,35 @@
+pkgname=haskell-mtl
+
+_register() {
+  usr/share/haskell/${pkgname}/register.sh
+}
+
+_unregister() {
+  usr/share/haskell/${pkgname}/unregister.sh
+}
+
+_gen_contents() {
+  (cd usr/share/doc/ghc/html/libraries; ./gen_contents_index)
+}
+
+post_install() {
+  _register
+  _gen_contents
+}
+
+pre_upgrade() {
+  _unregister
+}
+
+post_upgrade() {
+  _register
+  _gen_contents
+}
+
+pre_remove() {
+  _unregister
+}
+
+post_remove() {
+  _gen_contents
+}
-- 
cgit v1.2.3-54-g00ecf