From 8fbc0076a4827ddc6af92e0b9daa4c4c31450808 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Fri, 19 Jul 2013 01:10:32 -0700
Subject: Fri Jul 19 01:09:18 PDT 2013

---
 community/winff/PKGBUILD      | 56 +++++++++++++++++++++++++++++++++++++++++++
 community/winff/winff.install | 14 +++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 community/winff/PKGBUILD
 create mode 100644 community/winff/winff.install

(limited to 'community/winff')

diff --git a/community/winff/PKGBUILD b/community/winff/PKGBUILD
new file mode 100644
index 000000000..f342c14de
--- /dev/null
+++ b/community/winff/PKGBUILD
@@ -0,0 +1,56 @@
+# $Id: PKGBUILD 93143 2013-06-25 18:51:28Z arodseth $
+# Maintainer: Alexander Rødseth <rodseth@gmail.com>
+# Contributor: yugrotavele <yugrotavele at archlinux dot us>
+# Contributor: Paolo Stivanin <admin AT polslinux DOT it>
+
+pkgname=winff
+pkgver=1.5.0
+pkgrel=1
+pkgdesc='GUI for ffmpeg'
+url='http://code.google.com/p/winff/'
+license=('GPL3')
+arch=('x86_64' 'i686')
+depends=('ffmpeg' 'gtk2' 'xterm' 'hicolor-icon-theme')
+makedepends=('lazarus' 'lazarus-gtk2' 'gendesk')
+install="$pkgname.install"
+source=("http://winff.googlecode.com/files/winff-$pkgver-source.tar.gz")
+sha256sums=('e94e5a4c11038e9a30fc3f5ea9094f86415d02bd1f1a746808513bbd47ea5766')
+
+prepare() {
+  cd "$srcdir"
+
+  gendesk -n \
+    --pkgname "$pkgname" \
+    --pkgdesc "$pkgdesc" \
+    --genericname 'Video converter' \
+    --categories 'AudioVideo;AudioVideoEditing;GTK'
+}
+
+build() {
+  cd "$srcdir/$pkgname"
+
+  lazbuild --lazarusdir=/usr/lib/lazarus winff.lpr --ws=gtk2
+}
+
+package() {
+  cd "$srcdir"
+
+  install -Dm755 "$srcdir/$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
+  install -dm755 "$pkgdir/usr/share/winff/"
+  find . -name "*.xml" \
+    -exec install -Dm644 {} "$pkgdir/usr/share/winff/" \; &> /dev/null
+  install -Dm644 "$srcdir/winff.desktop" \
+    "$pkgdir/usr/share/applications/winff.desktop"
+  install -Dm644 "$srcdir/$pkgname/winff-icons/48x48/winff.png" \
+    "$pkgdir/usr/share/pixmaps/winff.png"
+  for size in 16x16 24x24 32x32 48x48; do
+    install -Dm644 "$srcdir/$pkgname/winff-icons/$size/winff.png" \
+      "$pkgdir/usr/share/icons/hicolor/$size/apps/winff.png"
+  done
+  install -dm755 "$pkgdir/usr/share/winff/languages/"
+  find . -name "*.po" \
+    -exec install -Dm644 {} "$pkgdir/usr/share/winff/languages/" \; &> /dev/null
+  rm -f "$srcdir/$pkgname/presets.xml"
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/community/winff/winff.install b/community/winff/winff.install
new file mode 100644
index 000000000..92e6750ef
--- /dev/null
+++ b/community/winff/winff.install
@@ -0,0 +1,14 @@
+post_install() {
+  xdg-icon-resource forceupdate --theme hicolor &>/dev/null
+  update-desktop-database -q
+}
+
+post_upgrade() {
+   post_install
+}
+
+post_remove() {
+  post_install
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v1.2.3-54-g00ecf