From f1ae949e08a764ac063703dc9bb7f0afd7c16e96 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Thu, 31 May 2012 00:03:48 +0000
Subject: Thu May 31 00:03:48 UTC 2012

---
 kde-unstable/kdewebdev/PKGBUILD | 70 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 kde-unstable/kdewebdev/PKGBUILD

(limited to 'kde-unstable/kdewebdev/PKGBUILD')

diff --git a/kde-unstable/kdewebdev/PKGBUILD b/kde-unstable/kdewebdev/PKGBUILD
new file mode 100644
index 000000000..09bda7df8
--- /dev/null
+++ b/kde-unstable/kdewebdev/PKGBUILD
@@ -0,0 +1,70 @@
+# $Id: PKGBUILD 160175 2012-05-29 23:13:44Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdewebdev
+pkgname=('kdewebdev-kfilereplace'
+         'kdewebdev-kimagemapeditor'
+         'kdewebdev-klinkstatus'
+         'kdewebdev-kommander')
+pkgver=4.8.80
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdewebdev')
+makedepends=('cmake' 'automoc4' 'ruby' 'tidyhtml' 'kdepimlibs' 'boost')
+source=("http://download.kde.org/unstable/${pkgver}/src/${pkgbase}-${pkgver}.tar.xz")
+sha1sums=('3190023d96038eb58dbaa59a25d5688f07e11559')
+
+build() {
+	cd $srcdir
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdewebdev-kfilereplace() {
+	pkgdesc='Search & Replace Tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kfilereplace/"
+	install='kdewebdev.install'
+	cd $srcdir/build/kfilereplace
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfilereplace
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kimagemapeditor() {
+	pkgdesc='HTML Image Map Editor'
+	depends=('kdebase-runtime')
+    url="http://www.kde.org/applications/development/kimagemapeditor/"
+	install='kdewebdev-kimagemapeditor.install'
+	cd $srcdir/build/kimagemapeditor
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kimagemapeditor
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-klinkstatus() {
+	pkgdesc='Link Checker'
+	depends=('kdebase-runtime' 'kdepimlibs' 'tidyhtml')
+    url="http://www.kde.org/applications/development/klinkstatus/"
+	install='kdewebdev.install'
+	cd $srcdir/build/klinkstatus
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/klinkstatus
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kommander() {
+	pkgdesc='Executor for Kommander dialogs'
+	depends=('kdebase-runtime')
+        url="http://www.kde.org/applications/development/kommander/"
+	cd $srcdir/build/kommander
+	make DESTDIR=$pkgdir install
+}
-- 
cgit v1.2.3-54-g00ecf