From 415856bdd4f48ab4f2732996f0bae58595092bbe Mon Sep 17 00:00:00 2001
From: Parabola <dev@list.parabolagnulinux.org>
Date: Tue, 5 Apr 2011 14:26:38 +0000
Subject: Tue Apr  5 14:26:38 UTC 2011

---
 libre/thunderbird-libre/PKGBUILD | 83 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 libre/thunderbird-libre/PKGBUILD

(limited to 'libre/thunderbird-libre/PKGBUILD')

diff --git a/libre/thunderbird-libre/PKGBUILD b/libre/thunderbird-libre/PKGBUILD
new file mode 100644
index 000000000..d5f546e3d
--- /dev/null
+++ b/libre/thunderbird-libre/PKGBUILD
@@ -0,0 +1,83 @@
+# $Id$
+# Contributor: Alexander Baldeck <alexander@archlinux.org>
+# Contributor: Dale Blount <dale@archlinux.org>
+# Contributor: Anders Bostrom <anders.bostrom@home.se>
+pkgname=thunderbird-libre
+pkgver=3.1.9
+pkgrel=1
+pkgdesc="Standalone Mail/News reader, with GNUZilla addons"
+arch=('i686' 'x86_64')
+license=('MPL' 'GPL')
+url="http://www.mozilla.org/projects/thunderbird"
+depends=('gtk2' 'gcc-libs' 'mozilla-common' 'nss' 'libxt' 'shared-mime-info' 'alsa-lib' 'dbus-glib' 'hunspell' 'sqlite3>=3.7.4' 'desktop-file-utils')
+makedepends=('zip' 'pkg-config' 'libgnomeui' 'python2' 'libidl2' 'wireless_tools' 'autoconf2.13')
+optdepends=('libcanberra: for sound support')
+replaces=('thunderbird')
+conflicts=('thunderbird')
+provides=("thunderbird=$pkgver")
+install=thunderbird.install
+source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/${pkgver}/source/thunderbird-${pkgver}.source.tar.bz2
+        mozconfig
+        thunderbird.desktop
+        thunderbird-3.0-lang.patch
+        thunderbird-appversion.patch
+        thunderbird-shared-error.patch
+        thunderbird-preferences.patch
+        xulrunner-png14.patch
+        python2.7.patch
+        gnuzilla-addons.patch)
+md5sums=('e6917c419d3aaa8083a1d4b53fb80d8c'
+         'c1551d308480d241247c5662d8bebbcb'
+         '37457073c7f6feeb86c053701d23197f'
+         '25b6fe16ac24cd5c852213e5c1adb272'
+         '48ffcdb877a69d383b7d354e330f7658'
+         '3dca714ee8054634e6dfdb059464dc42'
+         '1d4f9978e8228ace523b18a09cf41e4e'
+         '989b15f6bc9e2e9233fe4c6b23f412b1'
+         '78a4d0c920cbb8ec6a9a36974cd775ef'
+         'f272e37db4bcaef993b58a87a7db3bf5')
+
+build() {
+  cd "${srcdir}/comm-1.9.2"
+  patch -Np1 -i "${srcdir}/thunderbird-3.0-lang.patch"
+  patch -Np1 -i "${srcdir}/thunderbird-appversion.patch"
+  patch -Np1 -i "${srcdir}/thunderbird-shared-error.patch"
+  patch -Np1 -i "${srcdir}/thunderbird-preferences.patch"
+  patch -Np0 -i "${srcdir}/xulrunner-png14.patch"
+  patch -Np0 -i "${srcdir}/python2.7.patch"
+
+  pushd mail/app/profile >/dev/null
+  patch -Np0 -i "${srcdir}/gnuzilla-addons.patch"
+  popd >/dev/null
+
+  cp "${srcdir}/mozconfig" .mozconfig
+  unset CXXFLAGS
+  unset CFLAGS
+
+  export LDFLAGS="-Wl,-rpath,/usr/lib/thunderbird-3.1"
+
+  make -j1 -f client.mk build MOZ_MAKE_FLAGS="${MAKEFLAGS}"
+}
+
+package() {
+  cd "${srcdir}/comm-1.9.2"
+  make -j1 DESTDIR="${pkgdir}" install
+
+  #Remove included dictionaries, add symlink to system myspell path.
+  #Note: this will cause file conflicts when users have installed dictionaries in the old location
+  rm -rf "${pkgdir}/usr/lib/thunderbird-3.1/dictionaries"
+  ln -sf /usr/share/myspell/dicts "${pkgdir}/usr/lib/thunderbird-3.1/dictionaries"
+
+  rm -rf "${pkgdir}/usr/bin/defaults"
+
+  install -m755 -d "${pkgdir}/usr/share/applications"
+  install -m755 -d "${pkgdir}/usr/share/pixmaps"
+
+  install -m644 mail/branding/unofficial/mailicon48.png \
+  	"${pkgdir}/usr/share/pixmaps/thunderbird.png"
+
+  install -m644 "${srcdir}/thunderbird.desktop" \
+      "${pkgdir}/usr/share/applications/"
+
+  rm -f ${pkgdir}/usr/lib/pkgconfig/thunderbird-ns{s,pr}.pc
+}
-- 
cgit v1.2.3-54-g00ecf