From 415856bdd4f48ab4f2732996f0bae58595092bbe Mon Sep 17 00:00:00 2001
From: Parabola <dev@list.parabolagnulinux.org>
Date: Tue, 5 Apr 2011 14:26:38 +0000
Subject: Tue Apr  5 14:26:38 UTC 2011

---
 multilib/lib32-libpulse/PKGBUILD | 55 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 multilib/lib32-libpulse/PKGBUILD

(limited to 'multilib/lib32-libpulse')

diff --git a/multilib/lib32-libpulse/PKGBUILD b/multilib/lib32-libpulse/PKGBUILD
new file mode 100644
index 000000000..01f9efc6d
--- /dev/null
+++ b/multilib/lib32-libpulse/PKGBUILD
@@ -0,0 +1,55 @@
+# $Id: PKGBUILD 33577 2010-11-26 02:49:09Z heftig $
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=0.9.22
+pkgrel=1
+arch=(x86_64)
+url="http://pulseaudio.org/"
+license=(GPL LGPL)
+depends=(lib32-{dbus-core,xcb-util}
+         lib32-lib{asyncns,cap,xtst,sm,sndfile}
+         $_pkgbasename)
+makedepends=(pkgconfig gcc-multilib libtool-multilib intltool lib32-glib2 lib32-speex)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(!emptydirs !libtool !makeflags)
+source=("http://0pointer.de/lennart/projects/pulseaudio/pulseaudio-$pkgver.tar.gz")
+md5sums=('ca85ab470669b05e100861654cf5eb3c')
+
+_libs="libpulsecommon-$pkgver.la libpulse.la libpulse-simple.la libpulse-mainloop-glib.la libpulsedsp.la"
+
+build() {
+  cd "$srcdir/pulseaudio-$pkgver"
+
+  # Don't break circular dependency between libpulse and libpulsecommon
+  LDFLAGS="${LDFLAGS//-Wl,--as-needed}"
+
+
+  export CC="gcc -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --libdir=/usr/lib32 \
+    --libexecdir=/usr/lib32 \
+    --localstatedir=/var \
+    --disable-hal \
+    --disable-rpath \
+    --disable-default-build-tests
+
+  make -C src $_libs
+}
+
+package() {
+  cd "$srcdir/pulseaudio-$pkgver"
+  make -C src lib_LTLIBRARIES="$_libs" DESTDIR="$pkgdir" install-libLTLIBRARIES
+  make DESTDIR="$pkgdir" install-pkgconfigDATA
+}
-- 
cgit v1.2.3-54-g00ecf