From a1922d0ec660fdc1892f2783515f781c090df0a9 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Fri, 20 Jan 2012 23:14:48 +0000
Subject: Fri Jan 20 23:14:48 UTC 2012

---
 staging/graphicsmagick/PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 staging/graphicsmagick/PKGBUILD

(limited to 'staging/graphicsmagick')

diff --git a/staging/graphicsmagick/PKGBUILD b/staging/graphicsmagick/PKGBUILD
new file mode 100644
index 000000000..7ca0a92e3
--- /dev/null
+++ b/staging/graphicsmagick/PKGBUILD
@@ -0,0 +1,55 @@
+# $Id: PKGBUILD 146915 2012-01-19 05:34:57Z bisson $
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Gaetan Bisson <bisson@archlinux.org>
+# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
+# Contributor: Anton Leontiev <bunder@t-25.ru>
+
+pkgname=graphicsmagick
+pkgver=1.3.13
+pkgrel=2
+pkgdesc='Image processing system'
+url='http://www.graphicsmagick.org/'
+arch=('i686' 'x86_64')
+license=('MIT')
+makedepends=('perl')
+depends=('bzip2' 'freetype2' 'ghostscript' 'jasper' 'lcms2' 'xz'
+         'libtiff' 'libwmf' 'libsm' 'libxml2' 'libltdl')
+options=('!libtool')
+source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/GraphicsMagick-${pkgver}.tar.xz")
+sha1sums=('b85b21785bb072fd795f7fc6ac902cffae4e96e6')
+
+build() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+
+	./configure \
+		--prefix=/usr \
+		--with-perl \
+		--enable-shared \
+		--disable-static \
+		--with-gs-font-dir=/usr/share/fonts/Type1 \
+
+	make
+}
+
+package() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+
+	make DESTDIR="${pkgdir}" install
+
+	# Install MIT license
+	install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/${pkgname}/Copyright.txt"
+
+	# Install perl bindings
+	# The patching was introduced in order to build perl module without installing package itself and
+	# not to introduce unnecessary path into LD_RUN_PATH
+	cd PerlMagick
+	sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
+	perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
+	sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
+	make
+	make install
+
+	# Remove perllocal.pod and .packlist
+	rm -rf "${pkgdir}/usr/lib/perl5/core_perl"
+	rm "${pkgdir}/usr/lib/perl5/vendor_perl/auto/Graphics/Magick/.packlist"
+}
-- 
cgit v1.2.3-54-g00ecf