From 068f1f30c0bba25b6b88cefbe982a72535fa1951 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Wed, 5 Oct 2011 23:14:45 +0000
Subject: Wed Oct  5 23:14:44 UTC 2011

---
 staging/kdeadmin/PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 staging/kdeadmin/PKGBUILD

(limited to 'staging/kdeadmin/PKGBUILD')

diff --git a/staging/kdeadmin/PKGBUILD b/staging/kdeadmin/PKGBUILD
new file mode 100644
index 000000000..3b70775f1
--- /dev/null
+++ b/staging/kdeadmin/PKGBUILD
@@ -0,0 +1,77 @@
+# $Id: PKGBUILD 139778 2011-10-04 23:24:33Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdeadmin
+pkgname=('kdeadmin-kcron'
+         'kdeadmin-ksystemlog'
+         'kdeadmin-kuser'
+         'kdeadmin-system-config-printer-kde')
+pkgver=4.7.2
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdeadmin')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'kdebindings-python'
+	         'system-config-printer-common')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2"
+        'syslog-path.patch')
+sha1sums=('c96ddd94a4903b035e73b3e958e6b189ca173fe9'
+          '20095ce6e0f3e5b6800a7c6e52de6fddba62c031')
+
+build() {
+	cd ${srcdir}/${pkgbase}-${pkgver}
+	patch -p1 -i ${srcdir}/syslog-path.patch
+
+	cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DBUILD_strigi-analyzer=OFF
+	make
+}
+
+package_kdeadmin-kcron() {
+	pkgdesc='Configure and schedule tasks'
+	depends=('kdelibs')
+	cd $srcdir/build/kcron
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kcron
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-ksystemlog() {
+	pkgdesc='System log viewer tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/system/ksystemlog/"
+	cd $srcdir/build/ksystemlog
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/ksystemlog
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-kuser() {
+	pkgdesc='User Manager'
+	depends=('kdepim-runtime')
+	url="http://kde.org/applications/system/kuser/"
+	install='kdeadmin.install'
+	cd $srcdir/build/kuser
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kuser
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-system-config-printer-kde() {
+	pkgdesc='Configure local and remote Printers'
+	depends=('kdebindings-python' 'system-config-printer-common' 'python2-pyqt')
+	url="http://kde.org/applications/system/printerapplet/"
+	cd $srcdir/build/system-config-printer-kde
+	make DESTDIR=$pkgdir install
+
+    # Use the python2 executable
+    find ${pkgdir} -name '*.py' | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
+}
-- 
cgit v1.2.3-54-g00ecf