From 4d91fc9a2dc38054b8748f27193dc3a6950bda3c Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Tue, 7 Jun 2011 22:47:46 +0000
Subject: Tue Jun  7 22:47:46 UTC 2011

---
 staging/kdewebdev/PKGBUILD | 67 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 staging/kdewebdev/PKGBUILD

(limited to 'staging/kdewebdev/PKGBUILD')

diff --git a/staging/kdewebdev/PKGBUILD b/staging/kdewebdev/PKGBUILD
new file mode 100644
index 000000000..c56e2c824
--- /dev/null
+++ b/staging/kdewebdev/PKGBUILD
@@ -0,0 +1,67 @@
+# $Id: PKGBUILD 126546 2011-06-06 06:10:12Z andrea $
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdewebdev
+pkgname=('kdewebdev-kfilereplace'
+         'kdewebdev-kimagemapeditor'
+         'kdewebdev-klinkstatus'
+         'kdewebdev-kommander')
+pkgver=4.6.4
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdewebdev')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'ruby' 'tidyhtml' 'kdepim-runtime'
+	'boost')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('ef6b5142afd5b97ad8c1bffe0557e25477371344')
+
+build() {
+	cd $srcdir
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdewebdev-kfilereplace() {
+	pkgdesc='Search & Replace Tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kfilereplace/"
+	install='kdewebdev.install'
+	cd $srcdir/build/kfilereplace
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfilereplace
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kimagemapeditor() {
+	pkgdesc='HTML Image Map Editor'
+	depends=('kdebase-runtime')
+	install='kdewebdev.install'
+	cd $srcdir/build/kimagemapeditor
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kimagemapeditor
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-klinkstatus() {
+	pkgdesc='Link Checker'
+	depends=('kdepim-runtime' 'tidyhtml')
+	install='kdewebdev.install'
+	cd $srcdir/build/klinkstatus
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/klinkstatus
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kommander() {
+	pkgdesc='Executor for Kommander dialogs'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/kommander
+	make DESTDIR=$pkgdir install
+}
-- 
cgit v1.2.3-54-g00ecf