From 59075f0265483f32e9ac4c67ba9e69cb019ba044 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Fri, 8 Apr 2011 04:18:44 +0000
Subject: Fri Apr  8 04:18:44 UTC 2011

---
 testing/gnome-pilot/PKGBUILD            | 35 +++++++++++++++++++++++++++++++++
 testing/gnome-pilot/gnome-pilot.install | 17 ++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 testing/gnome-pilot/PKGBUILD
 create mode 100644 testing/gnome-pilot/gnome-pilot.install

(limited to 'testing/gnome-pilot')

diff --git a/testing/gnome-pilot/PKGBUILD b/testing/gnome-pilot/PKGBUILD
new file mode 100644
index 000000000..82d3c5c69
--- /dev/null
+++ b/testing/gnome-pilot/PKGBUILD
@@ -0,0 +1,35 @@
+# $Id: PKGBUILD 116045 2011-03-22 16:53:46Z heftig $
+# Jan de Groot <jgc@archlinux.org>
+
+pkgname=gnome-pilot
+pkgver=2.91.92
+pkgrel=1
+pkgdesc="Pilot Support for Gnome"
+arch=(i686 x86_64)
+license=('GPL')
+depends=('pilot-link' 'evolution-data-server')
+makedepends=('intltool' 'gob2' 'gnome-doc-utils' 'gnome-panel')
+optdepends=('gnome-panel')
+options=('!libtool' '!emptydirs')
+url="http://www.gnome.org"
+install=gnome-pilot.install
+source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
+sha256sums=('dc7a166c95580c2935b1cab822d9e6d63d5ef08bb19eacf4a84f6eda071f07c3')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --libexecdir=/usr/lib/gnome-pilot \
+      --localstatedir=/var --disable-static \
+      --without-hal
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
+
+  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
+  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
+  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
+}
diff --git a/testing/gnome-pilot/gnome-pilot.install b/testing/gnome-pilot/gnome-pilot.install
new file mode 100644
index 000000000..616daa0e4
--- /dev/null
+++ b/testing/gnome-pilot/gnome-pilot.install
@@ -0,0 +1,17 @@
+pkgname=gnome-pilot
+
+post_install() {
+  usr/sbin/gconfpkg --install ${pkgname}
+}
+
+pre_upgrade() {
+  pre_remove $1
+}
+
+post_upgrade() {
+  post_install $1
+}
+
+pre_remove() {
+  usr/sbin/gconfpkg --uninstall ${pkgname}
+}
-- 
cgit v1.2.3-54-g00ecf