From a522a5f63f3b5726081698bf742801fb1d242817 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Sun, 8 Jul 2012 00:04:04 +0000
Subject: Sun Jul  8 00:04:04 UTC 2012

---
 testing/vlc/PKGBUILD    | 89 +++++++++++++++++++++++++++++++++++++++++++++++++
 testing/vlc/vlc.install | 18 ++++++++++
 2 files changed, 107 insertions(+)
 create mode 100644 testing/vlc/PKGBUILD
 create mode 100644 testing/vlc/vlc.install

(limited to 'testing/vlc')

diff --git a/testing/vlc/PKGBUILD b/testing/vlc/PKGBUILD
new file mode 100644
index 000000000..6b303a952
--- /dev/null
+++ b/testing/vlc/PKGBUILD
@@ -0,0 +1,89 @@
+# $Id: PKGBUILD 163068 2012-07-06 15:22:25Z ibiru $
+# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
+# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
+# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
+
+pkgname=vlc
+pkgver=2.0.2
+pkgrel=2
+pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player"
+arch=('i686' 'x86_64')
+url="http://www.videolan.org/vlc/"
+license=('LGPL2.1' 'GPL2')
+depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'qt' 'libproxy' 
+         'sdl_image' 'libdvdnav' 'libtiger' 'lua' 'libmatroska' 
+         'zvbi' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libupnp' 
+         'libshout' 'libmad' 'libmpeg2' 'libmodplug' 'libass' 
+         'xcb-util-keysyms' 'ttf-freefont')
+makedepends=('live-media' 'libnotify' 'libbluray' 'flac' 'kdelibs'
+             'fluidsynth' 'libdc1394' 'libavc1394' 'lirc-utils'
+             'libcaca' 'librsvg' 'portaudio' 'oss' 'libgme' 'xosd'
+             'projectm' 'twolame' 'aalib' 'libmtp' 'libdvdcss'
+             'gnome-vfs' 'libgoom2' 'libtar' 'vcdimager')
+optdepends=('avahi: for service discovery using bonjour protocol'
+            'libnotify: for notification plugin'
+            'ncurses: for ncurses interface support'
+            'libdvdcss: for decoding encrypted DVDs'
+            'lirc-utils: for lirc plugin'
+            'libavc1394: for devices using the 1394ta AV/C'
+            'libdc1394: for IEEE 1394 plugin'
+            'kdelibs: KDE Solid hardware integration'
+            'vdpau-video: vdpau back-end for nvidia'
+            'libva-driver-intel: back-end for intel cards'
+            'libbluray: for Blu-Ray support'
+            'flac: for Free Lossless Audio Codec plugin'
+            'oss: for OSS audio support'
+            'portaudio: for portaudio support'
+            'twolame: for TwoLAME mpeg2 encoder plugin'
+            'projectm: for ProjectM visualisation plugin'
+            'libcaca: for colored ASCII art video output'
+            'libgme: for libgme plugin'
+            'librsvg: for SVG plugin'
+            'gnome-vfs: for GNOME Virtual File System support'
+            'libgoom2: for libgoom plugin'
+            'vcdimager: navigate VCD with libvcdinfo'
+            'xosd: for xosd support'
+            'aalib: for ASCII art plugin'
+            'libmtp: for MTP devices support'
+            'fluidsynth: for synthesizer MIDI FluidSynth'
+            'smbclient: for SMB access plugin'
+            'libcdio: for audio CD playback support')
+conflicts=('vlc-plugin')
+replaces=('vlc-plugin')
+backup=('usr/share/vlc/lua/http/.hosts'
+        'usr/share/vlc/lua/http/dialogs/.hosts')
+options=('!libtool' '!emptydirs')
+install=vlc.install
+source=("http://download.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
+md5sums=('93e729cc970a4535b3213dbef0e69528')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  sed -i -e 's:truetype/freefont:TTF:g' modules/text_renderer/freetype.c
+
+  ./configure --prefix=/usr \
+              --disable-rpath \
+              --enable-oss \
+              --enable-faad \
+              --enable-nls \
+              --enable-lirc \
+              --enable-pvr \
+              --enable-ncurses \
+              --enable-realrtsp \
+              --enable-xosd \
+              --enable-aa \
+              --enable-vcdx
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+
+  for res in 16 32 48 128; do
+    install -D -m644 "${srcdir}/vlc-${pkgver}/share/icons/${res}x${res}/vlc.png" \
+        "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
+  done
+}
diff --git a/testing/vlc/vlc.install b/testing/vlc/vlc.install
new file mode 100644
index 000000000..dc4961cae
--- /dev/null
+++ b/testing/vlc/vlc.install
@@ -0,0 +1,18 @@
+post_install() {
+    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+    usr/lib/vlc/vlc-cache-gen -f /usr/lib/vlc/plugins
+    update-desktop-database -q
+}
+
+post_upgrade() {
+    post_install
+}
+
+pre_remove() {
+    rm -f usr/lib/vlc/plugins/plugins-*.dat
+}
+
+post_remove() {
+    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+    update-desktop-database -q
+}
-- 
cgit v1.2.3-54-g00ecf