# $Id: PKGBUILD 76990 2012-10-03 00:51:46Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>

pkgbase=python-pyproj
pkgname=('python-pyproj' 'python2-pyproj')
pkgver=1.9.2
pkgrel=1
pkgdesc="Python interfaces to PROJ.4 library"
arch=('i686' 'x86_64')
url="http://code.google.com/p/pyproj"
license=('custom')
source=(http://pyproj.googlecode.com/files/pyproj-${pkgver}.tar.gz)
makedepends=('python' 'python2')
sha1sums=('a7a4bf95f3492e45704bccd4aeafe3bbe32fb023')

build() {
   cd "${srcdir}"

   cp -a pyproj-${pkgver}{,-python2}

   # Build python 3 module
   cd pyproj-${pkgver}
   python3 setup.py build

   # Build python 2 module
   cd ../pyproj-${pkgver}-python2
   python2 setup.py build
}

package_python-pyproj() {
   depends=('proj' 'python>=3.3')

   cd "${srcdir}"/pyproj-${pkgver}
   python3 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build

   install -dm755 "${pkgdir}"/usr/share/licenses/${pkgname}
   install -m644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_python2-pyproj() {
   depends=('proj' 'python2>=2.7')
   replaces=('pyproj')

   cd "${srcdir}"/pyproj-${pkgver}-python2
   python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build

   install -dm755 "${pkgdir}"/usr/share/licenses/${pkgname}
   install -m644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}