# $Id: PKGBUILD 111941 2014-05-27 08:42:52Z jgc $
# Maintainer : Martin Wimpress <code@flexion.org>
# Contributor: 3ED <krzysztof1987@gmail.com>

pkgname=caja-actions
pkgver=1.7.0
pkgrel=3
arch=('i686' 'x86_64')
pkgdesc="An extension for Caja which allows arbitrary programs to be launched via context menu."
url="https://github.com/NiceandGently/caja-actions"
license=('GPL')
depends=('caja' 'libgtop')
makedepends=('mate-common' 'yelp-tools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/NiceandGently/${pkgname}/archive/v${pkgver}.tar.gz")
sha256sums=('8f87122501be366ed4bd84209b0917f6d89a5336c6b1a8a92386372520f731f0')
install=${pkgname}.install

prepare() {
    cd "$srcdir/$pkgname-$pkgver"
    NOCONFIGURE=1 ./autogen.sh
}

build() {
    cd "$srcdir/$pkgname-$pkgver"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${pkgname} \
        --with-gtk=2 \
        --disable-static
    make
}

package() {
    cd "$srcdir/$pkgname-$pkgver"
    make DESTDIR="$pkgdir" install
}