# $Id: PKGBUILD 82534 2013-01-20 09:37:44Z lcarlier $
# Maintainer : Laurent Carlier <lordheavym@gmail.com>
# Contributor: dionydonny <dionydonny@gmail.com>
# Contributor: Ermanno <erm67@yahoo.it>

pkgname=chmsee
pkgver=2.0
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="A chm (MS HTML help file format) viewer based on xulrunner."
url="http://chmsee.googlecode.com/"
license=('GPL')
depends=('xulrunner>=18.0' 'xulrunner<=19.0' 'chmlib' 'desktop-file-utils')
makedepends=('python2')
#source=(chmsee-$pkgver.tar.gz::https://github.com/jungleji/chmsee/tarball/v$pkgver
#source=(https://github.com/jungleji/chmsee/archive/b2a3c2ad32bfe9db067665ea1928d7e130d1b5e7.zip
source=(https://chmsee.googlecode.com/files/${pkgname}-${pkgver}.tar.gz
        chmsee)
install=chmsee.install
md5sums=('a9a1e79094e5a2674caa3b1f1e34f5e7'
         '242a9390bc943cc38237fa71137fb26c')

build() {
  cd ${srcdir}/chmsee-*/src

  cp Makefile.arch Makefile
  sed -i -e 's/17.*/18.*/g' ../application.ini

  make -j1
}

package() {
  cd ${srcdir}/chmsee-*

  install -d ${pkgdir}/usr/share/chmsee
  cp -a * ${pkgdir}/usr/share/chmsee 
  rm -r ${pkgdir}/usr/share/chmsee/src
  install -Dm644 data/chmsee.desktop.in \
    ${pkgdir}/usr/share/applications/chmsee.desktop
  # Fix FS#25152
  sed -i -e 's/_//g' ${pkgdir}/usr/share/applications/chmsee.desktop
  #
  install -d ${pkgdir}/usr/share/pixmaps
  install -Dm644 data/chmsee-icon.png ${pkgdir}/usr/share/pixmaps
  install -Dm755 ${srcdir}/chmsee ${pkgdir}/usr/bin/chmsee
#  install -d ${pkgdir}/usr/share/icons
#  cp -a data/icons/* ${pkgdir}/usr/share/icons/
}