# $Id: PKGBUILD 99719 2013-10-30 23:13:52Z allan $
# Maintainer: Sébastien Luttringer
# Contributor: Valere Monseur <valere_monseur@hotmail.com>
# Contributor: Alessandro Sagratini <ale_sagra@hotmail.com>
# Contributor: Kevin Edmonds <edmondskevin@hotmail.com>

pkgname=conntrack-tools
pkgver=1.4.2
pkgrel=1
pkgdesc='Userspace tools to interact with the Netfilter connection tracking system'
arch=('i686' 'x86_64')
url='http://www.netfilter.org/projects/conntrack-tools'
license=('GPL2')
depends=('libnetfilter_conntrack'
         'libnetfilter_cttimeout'
         'libnetfilter_cthelper'
         'libnetfilter_queue')
backup=('etc/conntrackd.conf')
source=("http://www.netfilter.org/projects/$pkgname/files/$pkgname-$pkgver.tar.bz2"{,.sig}
        'conntrackd.service')
install=$pkgname.install
sha1sums=('50b89305bb689973d42a163c480dc77a5c0f6fe0'
          'SKIP'
          'ab888d59b98b673709d2d89554c668e2bea0cb86')

prepare() {
  sed -i -e 's,/etc/conntrackd/,/etc/,' -e 's,/var/lock/,/run/lock/,' \
    $pkgname-$pkgver/include/conntrackd.h
}


build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin
  make
}

package() {
  # install binaries
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  # systemd
  cd "$pkgdir"
  install -D -m 644 "$srcdir/conntrackd.service" usr/lib/systemd/system/conntrackd.service
  # install empty configuration files
  install -D -m 644 /dev/null etc/conntrackd.conf
}

# vim:set ts=2 sw=2 et: