# $Id: PKGBUILD 49481 2011-06-17 21:30:52Z jelle $
# Maintainer :
# Contribute : Jelle van der Waa <jelle@vdwaa.nl>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Ben <ben@benmazer.net>

pkgname=dosbox
pkgver=0.74
pkgrel=2
pkgdesc="An emulator with builtin DOS for running DOS Games"
arch=('i686' 'x86_64')
url="http://dosbox.sourceforge.net/"
license=('GPL')
depends=('sdl_net' 'zlib' 'sdl_sound' 'libgl' 'libpng' 'alsa-lib' 'gcc-libs')
makedepends=('mesa')
source=("http://downloads.sourceforge.net/${pkgname}/$pkgname-$pkgver.tar.gz"
	'dosbox.png' 'dosbox.desktop' 'gcc46.patch')

build(){
  cd ${srcdir}/${pkgname}-${pkgver}
  patch -Np1 -i $srcdir/gcc46.patch
  sed -i 's/png_check_sig/png_sig_cmp/' configure 
  ./configure   --prefix=/usr \
    --sysconfdir=/etc/dosbox  
  make 
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install 


  # install docs, make does not install them
  install -d $pkgdir/usr/share/doc/$pkgname
  install -Dm644 $srcdir/$pkgname-$pkgver/README $pkgdir/usr/share/doc/$pkgname/README
  install -Dm644 $srcdir/$pkgname-$pkgver/docs/README.video $pkgdir/usr/share/doc/$pkgname/README.video

  install -Dm644 ${srcdir}/${pkgname}.png \
    ${pkgdir}/usr/share/pixmaps/${pkgname}.png 
  install -Dm644 ${srcdir}/${pkgname}.desktop \
    ${pkgdir}/usr/share/applications/${pkgname}.desktop 
}
md5sums=('b9b240fa87104421962d14eee71351e8'
         '2aac25fc06979e375953fcc36824dc5e'
         '85169ca599028bee8e29e0b3b7b34dd8'
         '3fba2e3c7c43290319b2928f40ed30e5')