# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=fotoxx
pkgver=11.09
pkgrel=2
pkgdesc="A program for improving image files made with a digital camera"
url="http://kornelix.squarespace.com/fotoxx"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('gimp-ufraw' 'perl-exiftool' 'xdg-utils' 'desktop-file-utils')
optdepends=('mashup: for composing pages to print from within fotoxx' 'brasero: for burning')
source=("http://kornelix.squarespace.com/storage/downloads/$pkgname-$pkgver.tar.gz")
md5sums=('7001aec08a6291abf1c7c480b79cc38f')
install=fotoxx.install

build() {
  cd $srcdir/$pkgname-$pkgver
  sed -i 's+xdg-deskto+#xdg-deskto+' Makefile
  make PREFIX=/usr \
    CFLAGS+="-c `pkg-config --cflags gtk+-2.0`" \
    LFLAGS+="`pkg-config --libs gtk+-2.0 gthread-2.0`" 
  sed -i 's+^# ++' data/desktop 
  sed -i 's+@PREFIX@+/usr+' data/desktop 
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir PREFIX=/usr install
  rm $pkgdir/usr/share/applications/kornelix-$pkgname.desktop 
  install -Dm644 data/desktop \
    $pkgdir/usr/share/applications/$pkgname.desktop
}