# $Id: PKGBUILD 56182 2011-10-03 06:12:55Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>

pkgname=gnome-packagekit
pkgver=3.2.0
pkgrel=2
pkgdesc='Collection of graphical tools for PackageKit to be used in the GNOME desktop'
arch=('i686' 'x86_64')
url='http://www.packagekit.org/'
license=('GPL')
depends=('dconf' 'desktop-file-utils' 'gtk3' 'hicolor-icon-theme' 'libnotify'
         'packagekit')
makedepends=('gconf' 'gtk-doc' 'intltool' 'libcanberra' 'upower')
optdepends=('gnome-settings-daemon-updates: update and message notifications')
options=('!emptydirs' '!libtool')
install="$pkgname.install"
source=("http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz"
        'arch.patch')
sha256sums=('a91efca58ac0781f925927772281e72abf16314ef3b9577bf42f8ab3f5b5c0e9'
            '9c809ac3c8bbf870442e7bc4123c70b144930a287b28626be1b8bae95edf71ac')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -Np1 -i "$srcdir/arch.patch"
  sed -i 's@python@python2@' 'python/enum-convertor.py'

  export PYTHON=/usr/bin/python2
  ./configure --prefix=/usr \
	      --sysconfdir=/etc \
	      --disable-gtk-doc \
	      --disable-schemas-compile \
	      --disable-scrollkeeper
  make -s
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make -s DESTDIR="$pkgdir" install

  rm -rf "$pkgdir/usr/lib/gnome-settings-daemon-3.0/gtk-modules"
}