# $Id: PKGBUILD 113162 2014-06-14 19:22:15Z andyrtr $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Sebastian Sareyko <public@nooms.de>

pkgname=gnustep-gui
pkgver=0.24.0
pkgrel=2
pkgdesc="The GNUstep GUI class library"
arch=('i686' 'x86_64')
url="http://www.gnustep.org/"
license=('LGPL')
depends=('gnustep-back' 'aspell' 'gcc-libs' 'libcups' 'audiofile' 'libsndfile' 'giflib' 'libao')
makedepends=('gcc-objc' 'gnustep-base' 'gnustep-make')
conflicts=('gnustep-gui-svn')
groups=('gnustep-core')
options=('!makeflags')
source=(ftp://ftp.gnustep.org/pub/gnustep/core/$pkgname-$pkgver.tar.gz
        giflib-5.1.patch)
md5sums=('bd289f0c7b2626d093ad92364069b9a7'
         '78b6470b9a43ac7025621fef07d2faef')

prepare() {
  cd $srcdir/$pkgname-$pkgver
  patch -Np1 -i ../giflib-5.1.patch
}

build() {
  cd $srcdir/$pkgname-$pkgver
  . /etc/profile.d/GNUstep.sh
  ./configure --prefix=/usr --sysconfdir=/etc/GNUstep
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install
}